From b256b4b120d8269d4415eac0c354eb603a7bf953 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 6 Jan 2023 00:10:03 +0000
Subject: gentoo auto-resync : 06:01:2023 - 00:10:03

---
 .../dolphin-plugins-mercurial-22.12.1.ebuild       | 67 ++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.1.ebuild

(limited to 'kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.1.ebuild')

diff --git a/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.1.ebuild b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.1.ebuild
new file mode 100644
index 000000000000..354de22a6270
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}
-- 
cgit v1.2.3