From 616579b5d773c50af31ee56f00105d96ce641ca2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Aug 2021 10:30:13 +0100
Subject: gentoo resync : 14.08.2021

---
 .../dolphin-plugins-dropbox-21.08.0.ebuild         | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.08.0.ebuild

(limited to 'kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.08.0.ebuild')

diff --git a/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.08.0.ebuild b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.08.0.ebuild
new file mode 100644
index 000000000000..ddf0a2f99f4f
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.08.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="dropbox"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Dropbox service integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	net-misc/dropbox-cli
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}
-- 
cgit v1.2.3