From d42200bec37eef2a7478d88988ff00addd0a9202 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 25 Jan 2020 11:50:47 +0000
Subject: gentoo resync : 25.01.2020

---
 gui-apps/swaylock/swaylock-1.5.ebuild | 58 +++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 gui-apps/swaylock/swaylock-1.5.ebuild

(limited to 'gui-apps/swaylock/swaylock-1.5.ebuild')

diff --git a/gui-apps/swaylock/swaylock-1.5.ebuild b/gui-apps/swaylock/swaylock-1.5.ebuild
new file mode 100644
index 000000000000..1775122395b5
--- /dev/null
+++ b/gui-apps/swaylock/swaylock-1.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Screen locker for Wayland"
+HOMEPAGE="https://github.com/swaywm/swaylock"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="fish-completion +gdk-pixbuf +man +pam zsh-completion"
+
+DEPEND="
+	dev-libs/wayland
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	pam? ( sys-libs/pam )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		-Dpam=$(usex pam enabled disabled)
+		-Dgdk-pixbuf=$(usex gdk-pixbuf enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if [[ ${PV} != 9999 ]]; then
+		emesonargs+=("-Dswaylock-version=${PV}")
+	fi
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	if ! use pam; then
+		fcaps cap_sys_admin usr/bin/swaylock
+	fi
+}
-- 
cgit v1.2.3