From d42200bec37eef2a7478d88988ff00addd0a9202 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 25 Jan 2020 11:50:47 +0000
Subject: gentoo resync : 25.01.2020

---
 gui-apps/swayidle/swayidle-1.6.ebuild | 53 +++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 gui-apps/swayidle/swayidle-1.6.ebuild

(limited to 'gui-apps/swayidle/swayidle-1.6.ebuild')

diff --git a/gui-apps/swayidle/swayidle-1.6.ebuild b/gui-apps/swayidle/swayidle-1.6.ebuild
new file mode 100644
index 000000000000..8604bda55107
--- /dev/null
+++ b/gui-apps/swayidle/swayidle-1.6.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Idle management daemon for Wayland"
+HOMEPAGE="https://github.com/swaywm/swayidle"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind fish-completion +man systemd zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	dev-libs/wayland
+	elogind? ( >=sys-auth/elogind-237[policykit] )
+	systemd? ( >=sys-apps/systemd-237[policykit] )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+	if use systemd; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd")
+	elif use elogind; then
+		emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind")
+	else
+		emesonargs+=("-Dlogind=disabled")
+	fi
+
+	meson_src_configure
+}
-- 
cgit v1.2.3