From 62f67115b5c46134c34f88f4b1cbdacc19384c0a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 30 Sep 2018 11:19:18 +0100
Subject: gentoo resync : 30.09.2018

---
 .../gnome-shell-extensions-3.26.2-r1.ebuild        | 83 ++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.26.2-r1.ebuild

(limited to 'gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.26.2-r1.ebuild')

diff --git a/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.26.2-r1.ebuild b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.26.2-r1.ebuild
new file mode 100644
index 000000000000..4d6478b6b512
--- /dev/null
+++ b/gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.26.2-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 readme.gentoo-r1
+
+DESCRIPTION="JavaScript extensions for GNOME Shell"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.26:2
+	>=gnome-base/libgtop-2.28.3[introspection]
+	>=app-eselect/eselect-gnome-shell-extensions-20111211
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-libs/gjs-1.29
+	dev-libs/gobject-introspection:=
+	dev-libs/atk[introspection]
+	gnome-base/gnome-menus:3[introspection]
+	>=gnome-base/gnome-shell-3.14.2
+	media-libs/clutter:1.0[introspection]
+	net-libs/telepathy-glib[introspection]
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/pango[introspection]
+	x11-themes/adwaita-icon-theme
+	x11-wm/mutter[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.19.6
+	virtual/pkgconfig
+"
+# eautoreconf needs gnome-base/gnome-common
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Installed extensions installed are initially disabled by default.
+To change the system default and enable some extensions, you can use
+# eselect gnome-shell-extensions
+
+Alternatively, to enable/disable extensions on a per-user basis,
+you can use the https://extensions.gnome.org/ web interface, the
+gnome-extra/gnome-tweak-tool GUI, or modify the org.gnome.shell
+enabled-extensions gsettings key from the command line or a script."
+
+PATCHES=(
+	# Bug fixes and wayland compat to auto-move-windows, places-menu and window-list
+	# extensions from upstream gnome-3-26 branch, plus translation updates from there
+	"${WORKDIR}"/patches/
+)
+
+src_configure() {
+	gnome2_src_configure --enable-extensions=all
+}
+
+src_install() {
+	gnome2_src_install
+
+	local example="example@gnome-shell-extensions.gcampax.github.com"
+	if use examples; then
+		mv "${ED}usr/share/gnome-shell/extensions/${example}" \
+			"${ED}usr/share/doc/${PF}/" || die
+	else
+		rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3