From f69d6e2bc8ae2d4f9fd516b99d1dcbfdb78fa533 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 2 Feb 2024 23:45:38 +0000
Subject: gentoo auto-resync : 02:02:2024 - 23:45:38

---
 .../gnome-network-displays-0.92.1.ebuild           | 70 ++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 gnome-extra/gnome-network-displays/gnome-network-displays-0.92.1.ebuild

(limited to 'gnome-extra/gnome-network-displays/gnome-network-displays-0.92.1.ebuild')

diff --git a/gnome-extra/gnome-network-displays/gnome-network-displays-0.92.1.ebuild b/gnome-extra/gnome-network-displays/gnome-network-displays-0.92.1.ebuild
new file mode 100644
index 000000000000..c2aa8bc1a72b
--- /dev/null
+++ b/gnome-extra/gnome-network-displays/gnome-network-displays-0.92.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Stream the desktop to Wi-Fi Display capable devices"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-network-displays"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="firewalld test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	gnome-base/gnome-desktop:3
+	media-libs/gst-rtsp-server
+	media-libs/libpulse[glib]
+	media-plugins/gst-plugins-faac
+	media-plugins/gst-plugins-x264
+	media-plugins/gst-plugins-ximagesrc
+	>=gui-libs/gtk-4
+	>=net-misc/networkmanager-1.16.0[wifi]
+	>=dev-libs/libportal-0.7
+	>=gui-libs/libadwaita-1
+	net-dns/dnsmasq
+	net-wireless/wpa_supplicant[p2p]
+	sys-apps/xdg-desktop-portal[screencast(+)]
+	firewalld? ( net-firewall/firewalld )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/gettext
+	virtual/pkgconfig
+	dev-libs/protobuf-c
+	test? (
+		dev-libs/appstream-glib
+		dev-util/desktop-file-utils
+	)
+"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	# https://gitlab.gnome.org/GNOME/gnome-network-displays/-/issues/272
+	sed -i -e "s/args: \['validate'/args: \['--nonet', 'validate'/" \
+		data/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use firewalld firewalld_zone)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3