From 92a9a3adda432ad2b7af58e08f5493ed6dc81196 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 22 Sep 2023 11:16:57 +0100
Subject: gentoo auto-resync : 22:09:2023 - 11:16:57

---
 .../gnome-network-displays-0.90.5-r1.ebuild        | 67 ++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 gnome-extra/gnome-network-displays/gnome-network-displays-0.90.5-r1.ebuild

(limited to 'gnome-extra/gnome-network-displays/gnome-network-displays-0.90.5-r1.ebuild')

diff --git a/gnome-extra/gnome-network-displays/gnome-network-displays-0.90.5-r1.ebuild b/gnome-extra/gnome-network-displays/gnome-network-displays-0.90.5-r1.ebuild
new file mode 100644
index 000000000000..6b84d7472dd7
--- /dev/null
+++ b/gnome-extra/gnome-network-displays/gnome-network-displays-0.90.5-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Stream the desktop to Wi-Fi Display capable devices"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-network-displays"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="firewalld test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	gnome-base/gnome-desktop:3
+	media-libs/gst-rtsp-server
+	media-libs/libpulse[glib]
+	media-plugins/gst-plugins-faac
+	media-plugins/gst-plugins-x264
+	media-plugins/gst-plugins-ximagesrc
+	>=net-misc/networkmanager-1.16.0[wifi]
+	net-dns/dnsmasq
+	net-wireless/wpa_supplicant[p2p]
+	sys-apps/xdg-desktop-portal[screencast(+)]
+	x11-libs/gtk+:3
+	firewalld? ( net-firewall/firewalld )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		dev-libs/appstream-glib
+		dev-util/desktop-file-utils
+	)
+"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	# https://gitlab.gnome.org/GNOME/gnome-network-displays/-/issues/272
+	sed -i -e "s/args: \['validate'/args: \['--nonet', 'validate'/" \
+		data/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use firewalld firewalld_zone)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3