From c22e93ab35a8cb604c41623a7b2cda059c462b70 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 25 Oct 2022 21:54:27 +0100
Subject: gentoo auto-resync : 25:10:2022 - 21:54:27

---
 .../evolution-data-server-3.46.1.ebuild            | 144 +++++++++++++++++++++
 1 file changed, 144 insertions(+)
 create mode 100644 gnome-extra/evolution-data-server/evolution-data-server-3.46.1.ebuild

(limited to 'gnome-extra/evolution-data-server/evolution-data-server-3.46.1.ebuild')

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.46.1.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.46.1.ebuild
new file mode 100644
index 000000000000..54af15fb111a
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.46.1.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-data-server"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/63-26-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth vala +weather"
+REQUIRED_USE="
+	oauth? ( gtk )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+RDEPEND="
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17
+	>=dev-libs/glib-2.70:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4
+	>=dev-libs/nss-3.9
+	>=net-libs/libsoup-3.1.1:3.0
+	>=dev-libs/json-glib-1.0.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=x11-libs/gtk+-3.20:3
+		>=gui-libs/gtk-4.4:4
+		>=media-libs/libcanberra-0.25[gtk3]
+
+		oauth? (
+			>=net-libs/webkit-gtk-2.34.0:4.1
+			>=net-libs/webkit-gtk-2.36.0:5
+		)
+	)
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-4.2.0:4= )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		>=net-libs/libsoup-3.1.1:3.0[vala]
+		dev-libs/libical[vala]
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_setup
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+	  -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+	  -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_GTK4=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2_WEBKITGTK=$(usex oauth)
+		-DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=ON
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}
-- 
cgit v1.2.3