From 23b767af73549eeb4dd3069e09d0f2fcb88669a8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 22 Mar 2023 00:41:01 +0000
Subject: gentoo auto-resync : 22:03:2023 - 00:41:01

---
 gnome-base/Manifest.gz                             | Bin 5028 -> 5026 bytes
 gnome-base/gnome-control-center/Manifest           |   3 +
 .../gnome-control-center-44.0.ebuild               | 204 +++++++++++++++++++++
 gnome-base/gnome-settings-daemon/Manifest          |   2 +
 .../gnome-settings-daemon-44.0.ebuild              | 142 ++++++++++++++
 5 files changed, 351 insertions(+)
 create mode 100644 gnome-base/gnome-control-center/gnome-control-center-44.0.ebuild
 create mode 100644 gnome-base/gnome-settings-daemon/gnome-settings-daemon-44.0.ebuild

(limited to 'gnome-base')

diff --git a/gnome-base/Manifest.gz b/gnome-base/Manifest.gz
index fec80b1f0eb4..c53bc7b27d21 100644
Binary files a/gnome-base/Manifest.gz and b/gnome-base/Manifest.gz differ
diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index abd01b1c7d17..c519c6da0a01 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,8 +1,11 @@
 DIST gnome-control-center-43.0-patchset.tar.xz 5940 BLAKE2B 91f47272518175286943a160ef77338b0153aa700a75315708ec478627dda8353b21d257b2baed9961ba77700e43c5655be06591b447c442881f828dd7002622 SHA512 e4683e99f43d9c395238df02228a87df4798df53c936bc8d188e366653d9e75b5219b0b0d8eb66ad21141fc2f1a882b994b96cf523c26b8dc21edb854aa1f384
 DIST gnome-control-center-43.2.tar.xz 5724016 BLAKE2B 207254fe1f304bee3e209cbd09a23296324da06fb828e7d34814a04b70e74d61af7fe1ffbe8d809e803a3858c8369584e69fa7810972f20f828c57367dbd4917 SHA512 de4bdeb176da819323f4071d762e1a5cd048a2b44f615b662b23fcc11f3651a0f643ff21489fde21cb337f86e85392fac7d09a4cf5b549f755b8e8ec5c6aa915
 DIST gnome-control-center-43.4.1.tar.xz 5735068 BLAKE2B f0fe438d3ac5ac046d3dec7c0d8ed275edb2c6b001465b83bff28e0b4b7748328f980095483faec0a290653d0b2a24b9df767ee96b1b6b6f522a8bab25358cef SHA512 73cf74ba50c838b65033879de0d57eb4e2608d70a9888c6dda4ddd82e83024432d04492ab0c30c35753250bf52e7a05627d09da15f88c08abdd4b516cd70d324
+DIST gnome-control-center-44.0-patchset.tar.xz 6004 BLAKE2B a647cd83fe5d2283edc341afaa6d55661b905fea740729cf21679c3593e5e339aec507b835fd57c11d1fdde8db338b57ff8e24f464bb1296ad7a5bd1fb7319c3 SHA512 85cdcf4d55028550cfd871285729d265f1f8b74ec46ad656ada122f511ec617a21c5927923e4000f3a2d7ca08f49aafc28cecbd4ab840db377fa2d4054997b6f
+DIST gnome-control-center-44.0.tar.xz 7617244 BLAKE2B ea373d34967c5533361feb5ea65ceb9d3238a28f13b3b625381717cf6507ff85f71c27441ade0f26586def5792d874c5c4b54796c902e4222cb4bfe82d7695eb SHA512 c24a5ee6ea48a50d286799ddd520626d117e5708746e56698ba45d167db5bd555baef02609dc8a20f5d3b1c49322b9774db383e448ca7a09e5b9d1cd53176d01
 DIST gnome-control-center-gentoo-logo-dark.svg 14293 BLAKE2B 570e9326b8abe45849c31fd5cdb3fcfb1b2f18eac522f958928df5c3b747b0699f50a882f31cf7c0ae1f2138194f18596f738f42c942b57d340c53d46d82c551 SHA512 91227dafcf2091bb1568b0f9eec68b5e371ec64c9a6bc3605821f60d6bf2bd94dec0564f6a16a4a70d1db4d4df49fc25b6c910367bae3b85205cc609a9f2701b
 DIST gnome-control-center-gentoo-logo.svg 14288 BLAKE2B 371fc68b1015c8672db3e3858ae9077b1e3a9937e6add8690c39db36302ec031391c4d35e0c0b87094ca474a00c4187849e2d7111df34f43bc5bd7be52678527 SHA512 cf88933546de54ca15e2e830ac1086a78c4150f0ff59b8091e7e1cade5961c4e4cb83120a818a960b77841353ce3584ddc8f36b6edbde05543600283a143ad7b
 EBUILD gnome-control-center-43.2.ebuild 6826 BLAKE2B 8538b37afc557e8b3ab1ccb052251d147ec3be4b02c00824908dc3a6207a90bdd29bdb0db94a64279f3c8055e16ac181620acbf612e0526f026a1cf6f9def335 SHA512 545195df33a997d6b13b60b32184ed0d9bb176f60ef2334663a5843cd9c2f73f400bc72e807b2b66903351447b4dd9a47ad5f51b852698a9f8185db2f2d5f713
 EBUILD gnome-control-center-43.4.1.ebuild 6829 BLAKE2B 35fae2bc4482a2aef14568d113d3b70224091d9110266921c1e97709ae91842cea24e945d7af67958cb8b823e63e6fb1f5ca1d14c70bd69fccb1ca08dbc6fdd7 SHA512 d82802ed5a2f7856302e3558a6cccc0961f0af9670ed490b8c0abc5e7b7728eae06acdf5e01f060bc9f759f3945a300b5c87cd3953b5b7b5f3fc4464f45e6051
+EBUILD gnome-control-center-44.0.ebuild 6855 BLAKE2B 735440f3991770cbbb73a4deaa285bc650041c9ce414c4547bff5a052d7a2ca8109f3abff019b7fe9623cb2176e8ffbc51b4544baf9e88957bf7b5e37595c7d1 SHA512 80a87a503a399451e2a131caacd3386132739565c1eef647dbb03833ec6d91ee9dd1115f09cd37f9da92d85e5cbd5f60755f6ee03b3c16390c62c801ce225ade
 MISC metadata.xml 610 BLAKE2B 33cb646209b89a151b412f3a5be10b29cf85cde070e8a55b50f18417b02806763f940a1f56684ec8f494f9bd07258e9219b4dc2dc01ef6710aedc03bb609d42e SHA512 1d1fd521a3901c3601d3bd4ab78ac95c44d058fc0de2506df38c5ad8ba5156ff04c4b112b7a801a13f5ed9c37243c64629cf7038ca156196fa5f3229606a1f9c
diff --git a/gnome-base/gnome-control-center/gnome-control-center-44.0.ebuild b/gnome-base/gnome-control-center/gnome-control-center-44.0.ebuild
new file mode 100644
index 000000000000..0859b7e34a50
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-44.0.ebuild
@@ -0,0 +1,204 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-control-center"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-44.0-patchset.tar.xz"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-gentoo-logo.svg"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-gentoo-logo-dark.svg"
+# Logo is CC-BY-SA-2.5
+LICENSE="GPL-2+ CC-BY-SA-2.5"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+# meson.build depends on python unconditionally
+BDEPEND="${PYTHON_DEPS}"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	gnome-online-accounts? (
+		x11-libs/gtk+:3
+		>=net-libs/gnome-online-accounts-3.25.3:=
+	)
+	>=media-libs/libpulse-2.0[glib]
+	>=gui-libs/gtk-4.9.3:4[X,wayland=]
+	>=gui-libs/libadwaita-1.2.0:1
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.75.0:2
+	gnome-base/gnome-desktop:4=
+	>=gnome-base/gnome-settings-daemon-41.0[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-42_alpha
+	dev-libs/libxml2:2
+	>=sys-power/upower-0.99.8:=
+	>=dev-libs/libgudev-232
+	>=x11-libs/libX11-1.8
+	>=x11-libs/libXi-1.2
+	media-libs/libepoxy
+	app-crypt/gcr:0=
+	>=dev-libs/libpwquality-1.2.2
+	>=sys-auth/polkit-0.114
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=net-libs/libnma-1.10.2
+		>=net-misc/networkmanager-1.24.0[modemmanager]
+		>=net-misc/modemmanager-0.7.990:=
+	)
+	bluetooth? ( net-wireless/gnome-bluetooth:3= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.3.0:=
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	net-libs/gnutls:=
+	media-libs/gsound
+
+	x11-libs/pango
+"
+# media-libs/libcanberra[pulseaudio,sound] needed for Speaker tests in
+# Settings/Sound/Output/Output Device, bug #814110
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	media-libs/libcanberra[pulseaudio,sound]
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? (
+		app-admin/openrc-settingsd
+		sys-auth/elogind
+	)
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper
+	)
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 )
+	)
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+	networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+		x11-apps/setxkbmap
+	)
+"
+
+PATCHES=(
+	# Patches from gnome-43 branch
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		-Dprivileged_group=wheel
+		-Dsnap=false
+		$(meson_use test tests)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+		-Dmalcontent=false # unpackaged
+		-Ddistributor_logo=/usr/share/pixmaps/gnome-control-center-gentoo-logo.svg
+		-Ddark_mode_distributor_logo=/usr/share/pixmaps/gnome-control-center-gentoo-logo-dark.svg
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	insinto /usr/share/pixmaps
+	doins "${DISTDIR}"/gnome-control-center-gentoo-logo.svg
+	doins "${DISTDIR}"/gnome-control-center-gentoo-logo-dark.svg
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index 2841c0fc0347..89703ebc98a3 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -2,7 +2,9 @@ AUX 42.1-build-Make-wacom-optional-and-controllable-via-meson.patch 1759 BLAKE2B
 AUX gnome-settings-daemon-3.38.1-build-Allow-NM-optional-on-Linux.patch 694 BLAKE2B e4f32a376c2b1c55a396504e98c8a69d512bb9161a854482aa877023a2761e59d3fc682d724398ffb53bc138b010c33276071359d42ac19bcac2d9af87d42eef SHA512 618ad312b54709d0f95e5d881c2896c156246ae41eee1925f76b0a398b7ce6815a7466f8587f2291b07f7a34d1a3e1afb7df33823d9b52ebe8ad46a3f5f1e84d
 AUX org.gnome.settings-daemon.plugins.power.gschema.override 75 BLAKE2B 1c80bbb15e998de9f5fddc956dab862552ecc3734083391f124ef577dd2efb70e29efd230511cca83536dcd8c32118ecebcfe52b2927d6f0094540ec73a6ae23 SHA512 9c4b1e1b63b1a6d97eed962969704accca2fc53763a4b7806e2a3e4ff49ecc7d4a0d7f8253ff2e33d83e766908d852721ffa33f363aed7d04c20002bfdee173b
 DIST gnome-settings-daemon-43.0.tar.xz 1453808 BLAKE2B 365a1fe4d253e84b9fc355331688951e1428eaee421afbe052a16226c7006a420f28134b5fa02929bbb1d4250af243b02594444a4bdd208e5c41ed9e63e5f979 SHA512 8cc3ed73fa66d2cf72621db78be68e4fe01f292ab3987aff8cc67a1c67d910622e306c2d3e69a8dca5ac6517c8e57883faf02aec871c7aa1f1348d13ff1900a3
+DIST gnome-settings-daemon-44.0.tar.xz 1464004 BLAKE2B 2c32dbea04f2d5107eab934379f955393590aa1ce2a4b27368d4df493fc96a07c0b21942a3a8987f85dfff4c6945e455c9113c1250c8fde3559ade43f81989d9 SHA512 276d1c2e559e0297855cfc9fc7bd2ce4ae55e2b711222f1f1aae4802dc6499f51ea09bff8f44c5d7b9f0f5a32ab187c2ac4d8ee8e5f1754a186ac189b4e885da
 DIST gnome-settings-daemon-44.rc.tar.xz 1464024 BLAKE2B 2bd2393954ae71cf3f56fcd9cef6321311caeebeb784eb443014a738b80069c5bec7650e6ffcfc4bf632a65191f24dd5e3ac3d94bc4305c2d6ed11adfd5178db SHA512 c843ea01af5333913e6cb8a2d88971c7d6f4edb58688f8f94fbf670c0866ee9ca3812be228a5e08f73053449b78421e41344b2f7f22fcf7508028adde00ac81f
 EBUILD gnome-settings-daemon-43.0.ebuild 3541 BLAKE2B 84760b8c1226724569c53fb4e3f58462a93a09ffbe2479ee3cec2ba7abf5a6d97e3b8abd2c5f3726ccc31a41d5e230ecc18ac19f230b88459a53b4ecf3af4b8a SHA512 4289eade4976677b912ba357b6a7be0d5855a3045eb58ccbba273cb03182354732765b91a9b9844d1e8926cd083461dea8f0b90ca4cdb4d6eb9d891e0424aad7
+EBUILD gnome-settings-daemon-44.0.ebuild 3544 BLAKE2B 7ad60b440bb6e100ad204fd5c69130b9360a50d082a61eb16520e46b7a6bdbc7e883c9d41b862f497a51ca8734a613f5275621bf9d91949a381985eeb058eda7 SHA512 6a84a5ca8916a8e1e59f628979e8b77c6884054b3c65767533e03285a893a95667b17077d378181960ca8515812f07cf51912857ca6a7903fd51ea5a031c8bf2
 EBUILD gnome-settings-daemon-44_rc.ebuild 3644 BLAKE2B cb9dde97249df7d7b1350581f7c56f81a3f155be3a531cd3f0c3dddba176b3ed01aa398749257812969fd61229c01df8137bb21a6e7bbeee2f8fa105e69fa91b SHA512 55112c0c738045ad16347f79b033d38dc7dcf5911d3f73754a9d0b7736baec287f4b119d54b8271d686705155e7f657077fbeed4d4ac3b31820f1a4be9298d06
 MISC metadata.xml 663 BLAKE2B 27a0e4135576aeea4c6b962c90d894df06f92b3b015fab78246724ce7ca2f985cfde730f1f9c91f0cc01733f274c0225816e24fac2fca40c585b1a8667fd7d4d SHA512 e21c9dc181f13228662a2a91d7d8e0fedc6270f818a79308e270c9de788011379c155e835534ebb5dbd5f3b07a9e83ec618d9d85f81f46784007b380c6a7ef18
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-44.0.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-44.0.ebuild
new file mode 100644
index 000000000000..375a12984c7e
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-44.0.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom modemmanager networkmanager smartcard systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="^^ ( elogind systemd )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=sci-geosciences/geocode-glib-3.10:2
+	>=dev-libs/glib-2.58:2
+	>=gnome-base/gnome-desktop-3.37.1:3=
+	>=gnome-base/gsettings-desktop-schemas-42
+	>=x11-libs/gtk+-3.15.3:3[X,wayland?]
+	>=dev-libs/libgweather-4.2.0:4=
+	colord? (
+		>=x11-misc/colord-1.4.5:=
+		>=media-libs/lcms-2.2:2
+	)
+	media-libs/libcanberra[gtk3]
+	>=app-misc/geoclue-2.3.1:2.0
+	>=x11-libs/libnotify-0.7.3
+	>=media-sound/pulseaudio-12.99.3[glib]
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99.12:=
+	x11-libs/libX11
+	>=x11-libs/libXfixes-6.0.0
+	dev-libs/libgudev:=
+	wayland? ( dev-libs/wayland )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=x11-libs/pango-1.20.0
+		x11-libs/gdk-pixbuf:2
+	)
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	modemmanager? (
+		>=app-crypt/gcr-3.90.0:4=
+		>=net-misc/modemmanager-1.0:=
+	)
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	media-libs/alsa-lib
+	x11-libs/libXi
+	x11-libs/libXext
+	media-libs/fontconfig
+	systemd? (
+		>=sys-apps/systemd-243
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+# logind needed for power and session management, bug #464944
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+"
+# rfkill requires linux/rfkill.h, thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+BDEPEND="
+	sys-kernel/linux-headers
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	${PYTHON_DEPS}
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+		gnome-base/gnome-session
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/42.1-build-Make-wacom-optional-and-controllable-via-meson.patch
+	"${FILESDIR}"/${PN}-3.38.1-build-Allow-NM-optional-on-Linux.patch
+)
+
+python_check_deps() {
+	if use test; then
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+		-Dudev_dir="$(get_udevdir)"
+		$(meson_use systemd)
+		-Dalsa=true
+		-Dgudev=true
+		-Dgcr3=false
+		$(meson_use colord)
+		$(meson_use cups)
+		$(meson_use networkmanager network_manager)
+		-Drfkill=true
+		$(meson_use smartcard)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+		$(meson_use modemmanager wwan)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	# Don't auto-suspend by default on AC power
+	insinto /usr/share/glib-2.0/schemas
+	doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	udev_reload
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3