From 7b830374520118e805fdd214530a389653750f51 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 16 Sep 2023 17:00:58 +0100
Subject: gentoo auto-resync : 16:09:2023 - 17:00:58

---
 games-util/cartridges/cartridges-2.3.ebuild | 58 +++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 games-util/cartridges/cartridges-2.3.ebuild

(limited to 'games-util/cartridges/cartridges-2.3.ebuild')

diff --git a/games-util/cartridges/cartridges-2.3.ebuild b/games-util/cartridges/cartridges-2.3.ebuild
new file mode 100644
index 000000000000..05c8ac27f772
--- /dev/null
+++ b/games-util/cartridges/cartridges-2.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Simple game launcher written in Python using GTK4 and Libadwaita"
+HOMEPAGE="https://github.com/kra-mo/cartridges/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/kra-mo/${PN}.git"
+else
+	SRC_URI="https://github.com/kra-mo/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	gui-libs/gtk:4[introspection]
+	gui-libs/libadwaita:1[introspection]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/blueprint-compiler
+	dev-util/desktop-file-utils
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.5.4-dont-validate-appstream.patch )
+
+src_install() {
+	meson_src_install
+
+	python_fix_shebang "${ED}"/usr/bin
+	python_optimize "${ED}"/usr/share/cartridges/cartridges
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}
-- 
cgit v1.2.3