From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 .../colobot-data/colobot-data-0.2.0_alpha.ebuild   | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 games-strategy/colobot-data/colobot-data-0.2.0_alpha.ebuild

(limited to 'games-strategy/colobot-data/colobot-data-0.2.0_alpha.ebuild')

diff --git a/games-strategy/colobot-data/colobot-data-0.2.0_alpha.ebuild b/games-strategy/colobot-data/colobot-data-0.2.0_alpha.ebuild
new file mode 100644
index 000000000000..4800d0ed10c1
--- /dev/null
+++ b/games-strategy/colobot-data/colobot-data-0.2.0_alpha.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake python-any-r1
+
+MY_PV=${PV/_/-}
+MY_P=colobot-gold-${MY_PV}
+MUSIC_P=colobot-music_ogg_${MY_PV}
+
+DESCRIPTION="Data package for colobot (Colonize with Bots)"
+HOMEPAGE="https://colobot.info/"
+SRC_URI="
+	https://github.com/colobot/colobot-data/archive/${MY_P}.tar.gz -> ${MY_P}.data.tar.gz
+	music? (
+		https://colobot.info/files/music/${MUSIC_P}.tar.gz )"
+S=${WORKDIR}/${PN}-${MY_P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+music"
+
+BDEPEND=${PYTHON_DEPS}
+
+src_unpack() {
+	unpack "${MY_P}.data.tar.gz"
+	if use music; then
+		tar -x -f "${DISTDIR}/${MUSIC_P}.tar.gz" -C "${S}/music" || die "Failed to unpack music"
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	if use music; then
+		sed -i -e '/find_program(WGET wget)/d' -e '/if(NOT WGET)/,+2 d' music/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DMUSIC=$(usex music)
+		-DMUSIC_FLAC=OFF
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3