From a5b65c81168c90928784a1e92cda84ed5d6b9eb3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 25 Sep 2019 19:33:39 +0100
Subject: gentoo resync : 25.09.2019

---
 .../colobot-data/colobot-data-0.1.12.ebuild        | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 games-strategy/colobot-data/colobot-data-0.1.12.ebuild

(limited to 'games-strategy/colobot-data/colobot-data-0.1.12.ebuild')

diff --git a/games-strategy/colobot-data/colobot-data-0.1.12.ebuild b/games-strategy/colobot-data/colobot-data-0.1.12.ebuild
new file mode 100644
index 000000000000..1a76b184e5b1
--- /dev/null
+++ b/games-strategy/colobot-data/colobot-data-0.1.12.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+MY_P=colobot-gold-${PV}-alpha
+MUSIC_P=colobot-music_ogg_${PV}-alpha
+
+DESCRIPTION="Data package for colobot (Colonize with Bots)"
+HOMEPAGE="https://colobot.info/"
+SRC_URI="
+	https://github.com/colobot/colobot-data/archive/${MY_P}.tar.gz -> ${MY_P}.data.tar.gz
+	music? (
+		https://colobot.info/files/music/${MUSIC_P}.tar.gz )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+music"
+
+S="${WORKDIR}/${PN}-${MY_P}"
+
+src_unpack() {
+	unpack "${MY_P}.data.tar.gz"
+	if use music; then
+		tar -x -f "${DISTDIR}/${MUSIC_P}.tar.gz" -C "${S}/music" || die "Failed to unpack music"
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if use music; then
+		sed -i -e '/find_program(WGET wget)/d' -e '/if(NOT WGET)/,+2 d' music/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DMUSIC=$(usex music)
+		-DMUSIC_FLAC=OFF
+	)
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3