From 7c7c2c9727d6b2ff30945b5aea0d575e1c406d8b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 2 May 2018 14:13:35 +0100
Subject: gentoo resync : 02.05.2018

---
 games-sports/foobillard/foobillard-3.0a-r1.ebuild | 54 +++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 games-sports/foobillard/foobillard-3.0a-r1.ebuild

(limited to 'games-sports/foobillard/foobillard-3.0a-r1.ebuild')

diff --git a/games-sports/foobillard/foobillard-3.0a-r1.ebuild b/games-sports/foobillard/foobillard-3.0a-r1.ebuild
new file mode 100644
index 000000000000..02844b26cb97
--- /dev/null
+++ b/games-sports/foobillard/foobillard-3.0a-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools desktop flag-o-matic toolchain-funcs
+
+DESCRIPTION="8ball, 9ball, snooker and carambol game"
+HOMEPAGE="http://foobillard.sourceforge.net/"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="sdl video_cards_nvidia"
+
+DEPEND="x11-libs/libXaw
+	x11-libs/libXi
+	virtual/opengl
+	virtual/glu
+	>=media-libs/freetype-2.0.9:2
+	media-libs/libpng:0=
+	sdl? ( media-libs/libsdl[video] )
+	!sdl? ( media-libs/freeglut )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	eapply \
+		"${FILESDIR}"/${P}-no_nvidia.patch \
+		"${FILESDIR}"/${P}-fbsd.patch \
+		"${FILESDIR}"/${P}-as-needed.patch \
+		"${FILESDIR}"/${P}-gl-clamp.patch
+	mv configure.{in,ac}
+	rm aclocal.m4
+
+	eautoreconf
+}
+
+src_configure() {
+	use video_cards_nvidia && append-ldflags -L/usr/$(get_libdir)/opengl/nvidia/lib
+	econf \
+		--enable-sound \
+		$(use_enable sdl SDL) \
+		$(use_enable !sdl glut) \
+		$(use_enable video_cards_nvidia nvidia)
+}
+
+src_install() {
+	default
+	doman foobillard.6
+	newicon data/full_symbol.png foobillard.png
+	make_desktop_entry foobillard Foobillard
+}
-- 
cgit v1.2.3