From a1b20429e7e2ba1b44414459afd5a2b50788cd9c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 25 Jan 2023 08:07:03 +0000
Subject: gentoo auto-resync : 25:01:2023 - 08:07:03

---
 games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild | 65 ++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild

(limited to 'games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild')

diff --git a/games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild b/games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild
new file mode 100644
index 000000000000..01d5f7f78f03
--- /dev/null
+++ b/games-rpg/freedroidrpg/freedroidrpg-1.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-3 )
+PYTHON_COMPAT=( python3_{9..11} )
+inherit lua-single python-any-r1 xdg
+
+DESCRIPTION="Modification of the classical Freedroid engine into an RPG"
+HOMEPAGE="https://www.freedroid.org/"
+SRC_URI="https://ftp.osuosl.org/pub/freedroid/freedroidRPG-${PV}/freedroidRPG-${PV}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug devtools opengl profile +sound"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	media-libs/libpng:=
+	media-libs/libsdl[opengl?,sound?,video]
+	media-libs/sdl-gfx:=
+	media-libs/sdl-image[jpeg,png]
+	sys-libs/zlib:=
+	virtual/libintl
+	devtools? ( media-libs/sdl-ttf )
+	opengl? (
+		media-libs/glew:0=
+		media-libs/libglvnd[X]
+	)
+	sound? ( media-libs/sdl-mixer[vorbis] )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/gettext
+	app-alternatives/awk
+	virtual/pkgconfig"
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	python_fix_shebang src/gen_savestruct.py
+	rm data/sound/speak.py || die # unused, skip install + python rdep
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable debug backtrace)
+		$(use_enable debug)
+		$(use_enable devtools dev-tools)
+		$(use_enable opengl)
+		$(use_enable profile rtprof)
+		$(use_enable sound)
+		$(use_with debug extra-warnings)
+	)
+
+	econf "${econfargs[@]}"
+}
-- 
cgit v1.2.3