From 9452a6e87b6c2c70513bc47a2470bf9f1168920e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 13 Jun 2020 10:39:22 +0100
Subject: gentoo resync : 13.06.2020

---
 games-roguelike/angband/angband-4.2.1.ebuild | 106 +++++++++++++++++++++++++++
 1 file changed, 106 insertions(+)
 create mode 100644 games-roguelike/angband/angband-4.2.1.ebuild

(limited to 'games-roguelike/angband/angband-4.2.1.ebuild')

diff --git a/games-roguelike/angband/angband-4.2.1.ebuild b/games-roguelike/angband/angband-4.2.1.ebuild
new file mode 100644
index 000000000000..2582bae99159
--- /dev/null
+++ b/games-roguelike/angband/angband-4.2.1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg-utils
+
+MAJOR_PV=$(ver_cut 1-2)
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="https://rephial.org/"
+SRC_URI="https://rephial.org/downloads/${MAJOR_PV}/${P}.tar.gz
+	https://dev.gentoo.org/~steils/distfiles/${P}-man.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ncurses sdl sound +X"
+
+REQUIRED_USE="sound? ( sdl )
+	|| ( X ncurses )"
+
+RDEPEND="X? (
+		media-fonts/font-misc-misc
+		x11-libs/libX11
+	)
+	ncurses? ( sys-libs/ncurses:0=[unicode] )
+	sdl? (
+		media-libs/libsdl2[video,X]
+		media-libs/sdl2-image
+		media-libs/sdl2-ttf
+		sound? (
+			media-libs/libsdl2[sound]
+			media-libs/sdl2-mixer[mp3]
+		)
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
+	sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
+
+	if use !sound ; then
+		sed -i -e 's/sounds//' lib/Makefile || die
+	fi
+
+	# Game constant files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	{
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/customize/\""
+		echo "CONFIG_PROTECT_MASK=\"/etc/${PN}/gamedata/\""
+	} > "${T}"/99${PN} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--bindir="${EPREFIX}"/usr/bin
+		--with-private-dirs
+		$(use_enable X x11)
+		$(use_enable ncurses curses)
+	)
+	if use sdl; then
+		myconf+=(
+			--enable-sdl2
+			$(use_enable sound sdl2-mixer)
+		)
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc changes.txt README.md
+	doman "${WORKDIR}"/${PN}.1
+	doenvd "${T}"/99${PN}
+
+	if use X || use sdl; then
+		use X && make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
+		use sdl && make_desktop_entry "angband -msdl2" "Angband (SDL2)" "${PN}"
+
+		local s
+		for s in 16 32 128 256 512; do
+			newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
+		done
+		newicon -s scalable lib/icons/att.svg "${PN}.svg"
+	fi
+}
+
+pkg_postinst() {
+	if use X || use sdl; then
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use X || use sdl; then
+		xdg_icon_cache_update
+	fi
+}
-- 
cgit v1.2.3