From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 games-puzzle/xbomb/xbomb-2.2b-r3.ebuild | 57 +++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 games-puzzle/xbomb/xbomb-2.2b-r3.ebuild

(limited to 'games-puzzle/xbomb/xbomb-2.2b-r3.ebuild')

diff --git a/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild b/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild
new file mode 100644
index 000000000000..ac1174f80e21
--- /dev/null
+++ b/games-puzzle/xbomb/xbomb-2.2b-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Minesweeper clone with hexagonal, rectangular and triangular grid"
+HOMEPAGE="http://www.gedanken.org.uk/software/xbomb/"
+SRC_URI="http://www.gedanken.org.uk/software/xbomb/download/${P}.tgz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+DEPEND="
+	acct-group/gamestat
+	x11-libs/libX11
+	x11-libs/libXaw
+	x11-libs/libXt
+"
+RDEPEND="
+	${DEPEND}
+	media-fonts/font-misc-misc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-DESTDIR.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e '/strip/d' Makefile || die
+	sed -i \
+		-e "s:/var/tmp:${EPREFIX}/var/games/${PN}:g" \
+		hiscore.c || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	einstalldocs
+
+	dodir /var/games/${PN}
+	touch "${ED}"/var/games/${PN}/${PN}{3,4,6}.hi || die "touch failed"
+
+	fowners :gamestat /var/games/${PN}{,/${PN}{3,4,6}.hi} /usr/bin/${PN}
+	fperms 660 /var/games/${PN}/${PN}{3,4,6}.hi
+	fperms g+s /usr/bin/${PN}
+
+	make_desktop_entry xbomb XBomb
+}
-- 
cgit v1.2.3