From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 games-puzzle/xbomb/xbomb-2.2b-r2.ebuild | 55 +++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 games-puzzle/xbomb/xbomb-2.2b-r2.ebuild

(limited to 'games-puzzle/xbomb/xbomb-2.2b-r2.ebuild')

diff --git a/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild b/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild
new file mode 100644
index 000000000000..d43f0aec54a7
--- /dev/null
+++ b/games-puzzle/xbomb/xbomb-2.2b-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Minesweeper clone with hexagonal, rectangular and triangular grid"
+HOMEPAGE="http://www.gedanken.org.uk/software/xbomb/"
+SRC_URI="http://www.gedanken.org.uk/software/xbomb/download/${P}.tgz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+DEPEND="x11-libs/libXaw"
+RDEPEND="
+	${DEPEND}
+	acct-group/gamestat
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-DESTDIR.patch
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/strip/d' \
+		-e '/^CC=/d' \
+		-e "/^CFLAGS/ { s:=.*:=${CFLAGS}: }" \
+		Makefile || die
+	sed -i \
+		-e "s:/var/tmp:/var/lib/${PN}:g" \
+		hiscore.c || die
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	default
+
+	dodir /var/lib/${PN}
+	touch "${ED}"/var/lib/${PN}/${PN}{3,4,6}.hi || die "touch failed"
+	fperms 660 /var/lib/${PN}/${PN}{3,4,6}.hi
+
+	fowners root:gamestat /var/lib/${PN} /usr/bin/${PN}
+	fperms g+s /usr/bin/${PN}
+
+	make_desktop_entry xbomb XBomb
+}
-- 
cgit v1.2.3