From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 games-puzzle/braid-hb/braid-hb-20150611.ebuild | 55 ++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 games-puzzle/braid-hb/braid-hb-20150611.ebuild

(limited to 'games-puzzle/braid-hb/braid-hb-20150611.ebuild')

diff --git a/games-puzzle/braid-hb/braid-hb-20150611.ebuild b/games-puzzle/braid-hb/braid-hb-20150611.ebuild
new file mode 100644
index 000000000000..e289db38e3e0
--- /dev/null
+++ b/games-puzzle/braid-hb/braid-hb-20150611.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker wrapper xdg
+
+MY_PN="braid"
+DESCRIPTION="Platform game where you manipulate flow of time"
+HOMEPAGE="https://www.humblebundle.com/store/braid"
+SRC_URI="BraidSetup-${PV:0:4}-${PV:4:2}-${PV:6:2}.sh"
+
+LICENSE="all-rights-reserved Arphic CC-BY-NC-SA-1.0"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+RDEPEND="
+	media-gfx/nvidia-cg-toolkit[abi_x86_32]
+	media-libs/libsdl2[joystick,opengl,sound,video,abi_x86_32]
+	virtual/opengl[abi_x86_32]
+	x11-libs/fltk:1[abi_x86_32]
+	x11-libs/libX11[abi_x86_32]
+	!${CATEGORY}/${MY_PN}-gog
+"
+
+S="${WORKDIR}/data"
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  ${HOMEPAGE}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	exeinto "${DIR}"
+	insinto "${DIR}"
+
+	doexe x86/{Braid,launcher}.bin.x86
+	doins -r noarch/{data,Icon.*}
+	dodoc noarch/READ_ME.txt
+
+	make_wrapper ${MY_PN} ./launcher.bin.x86 "${DIR}" /usr/$(ABI=x86 get_libdir)/fltk
+	make_desktop_entry ${MY_PN} Braid "${EPREFIX}${DIR}"/Icon.png
+}
-- 
cgit v1.2.3