From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 .../blackshades/blackshades-20070723-r1.ebuild     | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 games-fps/blackshades/blackshades-20070723-r1.ebuild

(limited to 'games-fps/blackshades/blackshades-20070723-r1.ebuild')

diff --git a/games-fps/blackshades/blackshades-20070723-r1.ebuild b/games-fps/blackshades/blackshades-20070723-r1.ebuild
new file mode 100644
index 000000000000..a531ebbe5987
--- /dev/null
+++ b/games-fps/blackshades/blackshades-20070723-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="You control a psychic bodyguard, and try to protect the VIP"
+HOMEPAGE="http://www.wolfire.com/blackshades.html
+	http://www.icculus.org/blackshades/"
+SRC_URI="http://filesingularity.timedoctor.org/Textures.tar.bz2
+	mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="blackshades"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	media-libs/freealut
+	media-libs/libsdl
+	media-libs/libvorbis
+	media-libs/openal
+	virtual/glu
+	virtual/opengl"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-datadir.patch
+)
+
+src_prepare() {
+	default
+
+	rm -rf Data/Textures || die
+	rm -f ../Textures/{,Blood/}._* || die
+	mv -f ../Textures Data || die "mv failed"
+	sed -i \
+		-e "s/-O2 \(-Wall\) -g/${CXXFLAGS} \1/" \
+		-e "/^LINKER/s:$: ${LDFLAGS}:" \
+		Makefile \
+		|| die "sed Makefile failed"
+	sed -i "s:@DATADIR@:/usr/share/${PN}:" \
+		Source/Main.cpp \
+		|| die "sed Main.cpp failed"
+}
+
+src_compile() {
+	emake bindir
+	emake
+}
+
+src_install() {
+	newbin objs/blackshades ${PN}
+	insinto /usr/share/${PN}
+	doins -r Data
+	dodoc IF_THIS_IS_A_README_YOU_HAVE_WON Readme TODO uDevGame_Readme
+	make_desktop_entry ${PN} "Black Shades"
+}
-- 
cgit v1.2.3