From 36ac65103bf5503e5bad1ecc7e8cb9e7643f6840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:49:31 +0100
Subject: Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.
---
 games-engines/odamex/odamex-0.8.1.ebuild | 81 ++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)
 create mode 100644 games-engines/odamex/odamex-0.8.1.ebuild

(limited to 'games-engines/odamex/odamex-0.8.1.ebuild')

diff --git a/games-engines/odamex/odamex-0.8.1.ebuild b/games-engines/odamex/odamex-0.8.1.ebuild
new file mode 100644
index 000000000000..8cfa9cbee75a
--- /dev/null
+++ b/games-engines/odamex/odamex-0.8.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+WX_GTK_VER="3.0-gtk3"
+inherit cmake-utils desktop wxwidgets xdg
+
+DESCRIPTION="Online multiplayer free software engine for DOOM"
+HOMEPAGE="https://odamex.net/"
+SRC_URI="mirror://sourceforge/${PN}/Odamex/${PV}/${PN}-src-${PV}.tar.bz2"
+
+LICENSE="GPL-2+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client master +odalaunch portmidi server upnp X"
+REQUIRED_USE="|| ( client master server )"
+
+RDEPEND="
+	client? (
+		media-libs/libpng:0=
+		media-libs/libsdl2[joystick,sound,video]
+		media-libs/sdl2-mixer
+		odalaunch? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+		portmidi? ( media-libs/portmidi )
+		X? ( x11-libs/libX11 )
+	)
+	server? (
+		upnp? ( net-libs/miniupnpc:= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="games-util/deutex"
+
+S="${WORKDIR}/${PN}-src-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-miniupnpc.patch
+)
+
+src_prepare() {
+	rm -r libraries/libminiupnpc odamex.wad || die
+
+	setup-wxwidgets
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_MASTER=$(usex master)
+		-DBUILD_ODALAUNCH=$(usex odalaunch)
+		-DBUILD_SERVER=$(usex server)
+		-DENABLE_PORTMIDI=$(usex portmidi)
+		-DUSE_MINIUPNP=$(usex upnp)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	# Build odamex.wad
+	cd wad || die "cd failed"
+	deutex -rgb 0 255 255 -doom2 bootstrap -build wadinfo.txt ../odamex.wad || die
+}
+
+src_install() {
+	if use client ; then
+		newicon -s 128 "${S}/media/icon_${PN}_128.png" "${PN}.png"
+		make_desktop_entry "${PN} -waddir /usr/share/doom" "Odamex"
+
+		if use odalaunch ; then
+			newicon -s 128 "${S}/media/icon_odalaunch_128.png" "odalaunch.png"
+			make_desktop_entry odalaunch "Odamex Launcher" odalaunch
+		fi
+	fi
+
+	cmake-utils_src_install
+}
-- 
cgit v1.2.3