From e3cf2c86fca1750343c1885311f857f185ee4f2d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 8 Sep 2019 01:07:24 +0100
Subject: gentoo resync : 08.09.2019

---
 games-engines/box2d/box2d-2.3.1.ebuild | 43 ++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 games-engines/box2d/box2d-2.3.1.ebuild

(limited to 'games-engines/box2d/box2d-2.3.1.ebuild')

diff --git a/games-engines/box2d/box2d-2.3.1.ebuild b/games-engines/box2d/box2d-2.3.1.ebuild
new file mode 100644
index 000000000000..9a083d4ffb02
--- /dev/null
+++ b/games-engines/box2d/box2d-2.3.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson multilib
+
+MY_PN="Box2D"
+DESCRIPTION="A C++ engine for simulating rigid bodies in 2D games"
+HOMEPAGE="https://box2d.org/"
+SRC_URI="https://github.com/erincatto/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="ZLIB"
+SLOT="$(ver_cut 1-2).0"
+KEYWORDS="~amd64 ~x86"
+
+S="${WORKDIR}/${MY_PN}-${PV}/${MY_PN}"
+
+src_prepare() {
+	# This version supports CMake but upstream has dropped it since this
+	# release. They now use Premake but this Meson file is actually
+	# simpler! Installation is manual but that's true for Premake too.
+	cat > meson.build <<EOF || die
+project('${MY_PN}', 'cpp')
+shared_library(
+	'${MY_PN}',
+	$(find ${MY_PN} -name "*.cpp" -printf "'%p', ")
+	soversion: '${SLOT}', install : true
+)
+EOF
+
+	default
+}
+
+src_install() {
+	dodoc {Changes,Readme}.txt
+	dolib.so "${BUILD_DIR}"/lib${MY_PN}$(get_libname ${SLOT})
+
+	local FILE
+	for FILE in $(find ${MY_PN} -name *.h); do
+		insinto "/usr/include/${MY_PN}-${SLOT}/${FILE%/*}"
+		doins "${FILE}"
+	done
+}
-- 
cgit v1.2.3