From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 games-board/pysolfc/pysolfc-2.0-r5.ebuild | 64 +++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 games-board/pysolfc/pysolfc-2.0-r5.ebuild

(limited to 'games-board/pysolfc/pysolfc-2.0-r5.ebuild')

diff --git a/games-board/pysolfc/pysolfc-2.0-r5.ebuild b/games-board/pysolfc/pysolfc-2.0-r5.ebuild
new file mode 100644
index 000000000000..b98ccfee931b
--- /dev/null
+++ b/games-board/pysolfc/pysolfc-2.0-r5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="tk"
+DISTUTILS_SINGLE_IMPL="1"
+
+inherit eutils distutils-r1
+
+MY_PN=PySolFC
+SOL_URI="mirror://sourceforge/${PN}"
+
+DESCRIPTION="An exciting collection of more than 1000 solitaire card games"
+HOMEPAGE="http://pysolfc.sourceforge.net/"
+SRC_URI="${SOL_URI}/${MY_PN}-${PV}.tar.bz2
+	extra-cardsets? ( ${SOL_URI}/${MY_PN}-Cardsets-${PV}.tar.bz2 )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="extra-cardsets minimal +sound"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+DEPEND=""
+RDEPEND="${RDEPEND}
+	!minimal? ( dev-python/pillow[tk,${PYTHON_USEDEP}]
+		dev-tcltk/tktable )
+	sound? ( dev-python/pygame[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-PIL-imports.patch" #471514
+	"${FILESDIR}/${PN}-gentoo.patch" #591904
+)
+
+python_prepare_all() {
+	sed -i \
+		-e "/pysol.desktop/d" \
+		-e "s:share/icons:share/pixmaps:" \
+		-e "s:data_dir =.*:data_dir = \'/usr/share/${PN}\':" \
+		setup.py || die
+
+	mv docs/README{,.txt} || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	make_desktop_entry pysol.py "PySol Fan Club Edition" pysol02
+
+	if use extra-cardsets; then
+		insinto /usr/share/${PN}
+		doins -r "${WORKDIR}"/${MY_PN}-Cardsets-${PV}/*
+	fi
+
+	doman docs/*.6
+
+	DOCS=( README AUTHORS docs/README.txt docs/README.SOURCE )
+	HTML_DOCS=( docs/*html )
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3