From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 .../moleinvasion/moleinvasion-0.4-r3.ebuild        | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 games-arcade/moleinvasion/moleinvasion-0.4-r3.ebuild

(limited to 'games-arcade/moleinvasion/moleinvasion-0.4-r3.ebuild')

diff --git a/games-arcade/moleinvasion/moleinvasion-0.4-r3.ebuild b/games-arcade/moleinvasion/moleinvasion-0.4-r3.ebuild
new file mode 100644
index 000000000000..3bd4d5e35124
--- /dev/null
+++ b/games-arcade/moleinvasion/moleinvasion-0.4-r3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Mole infested 2D platform game"
+HOMEPAGE="http://moleinvasion.tuxfamily.org/"
+SRC_URI="
+	ftp://download.tuxfamily.org/minvasion/packages/MoleInvasion-${PV}.tar.bz2
+	music? ( mirror://gentoo/${PN}-music-20090731.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="music"
+
+DEPEND="
+	media-libs/libsdl[joystick,opengl,video]
+	media-libs/sdl-image[jpeg,png]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-ttf
+	virtual/opengl"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P}/src"
+
+src_prepare() {
+	default
+
+	if use music; then
+		mv -f "${WORKDIR}"/music ../ || die
+	fi
+
+	sed -i \
+		-e '/^CFLAGS/s:= -g:+=:' \
+		-e '/^LDFLAGS/d' \
+		-e "/^FINALEXEDIR/s:/usr.*:/usr/bin:" \
+		-e "/^FINALDATADIR/s:/usr.*:/usr/share/${PN}:" \
+		Makefile || die "sed failed"
+
+	eapply \
+		"${FILESDIR}"/${P}-opengl.patch \
+		"${FILESDIR}"/${P}-underlink.patch \
+		"${FILESDIR}"/${P}-fno-common.patch
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-data
+	doman ../debian/*.6
+
+	newicon ../gfx/icon.xpm moleinvasion.xpm
+	make_desktop_entry moleinvasion "Mole Invasion"
+}
-- 
cgit v1.2.3