From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 .../defendguin/defendguin-0.0.12-r2.ebuild         | 44 ++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 games-arcade/defendguin/defendguin-0.0.12-r2.ebuild

(limited to 'games-arcade/defendguin/defendguin-0.0.12-r2.ebuild')

diff --git a/games-arcade/defendguin/defendguin-0.0.12-r2.ebuild b/games-arcade/defendguin/defendguin-0.0.12-r2.ebuild
new file mode 100644
index 000000000000..31b4eb2280dc
--- /dev/null
+++ b/games-arcade/defendguin/defendguin-0.0.12-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Clone of the arcade game Defender, but with a Linux theme"
+HOMEPAGE="http://www.newbreedsoftware.com/defendguin/"
+SRC_URI="
+	ftp://ftp.tuxpaint.org/unix/x/defendguin/src/${P}.tar.gz
+	https://dev.gentoo.org/~ionen/distfiles/${PN}.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	media-libs/libsdl[joystick,sound,video]
+	media-libs/sdl-mixer[mod]"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	tc-export CC
+	sed	-e "s|\$(DATA_PREFIX)|${EPREFIX}/usr/share/${PN}/|" \
+		-e '/^CFLAGS=.*-O2/d' \
+		-e '/^CFLAGS=/s|=|+= $(CPPFLAGS) $(LDFLAGS) |' \
+		-i Makefile || die
+	rm data/images/l2r.sh || die
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins -r data/.
+
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} ${PN^}
+
+	doman src/${PN}.6
+	dodoc docs/{AUTHORS,CHANGES,README,TODO}.txt
+}
-- 
cgit v1.2.3