From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 games-action/wordwarvi/wordwarvi-1.00-r1.ebuild | 59 +++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 games-action/wordwarvi/wordwarvi-1.00-r1.ebuild

(limited to 'games-action/wordwarvi/wordwarvi-1.00-r1.ebuild')

diff --git a/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild b/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild
new file mode 100644
index 000000000000..df7ee9102eb8
--- /dev/null
+++ b/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="A retro side-scrolling shoot'em up based on the editor war story"
+HOMEPAGE="http://wordwarvi.sourceforge.net"
+SRC_URI="mirror://sourceforge/wordwarvi/${P}.tar.gz"
+
+LICENSE="GPL-2 CC-BY-2.0 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="portaudio"
+
+RDEPEND="x11-libs/gtk+:2
+	portaudio? ( media-libs/libvorbis
+		>=media-libs/portaudio-19_pre1 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-sound.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^WITHAUDIO/s/yes/$(use portaudio && echo yes || echo no)/" \
+		Makefile || die
+	sed -i \
+		-e "s:GENTOO_DATADIR:/usr/share/${PN}:" \
+		wwviaudio.c || die
+}
+
+src_compile() {
+	emake \
+		PREFIX="/usr" \
+		DATADIR="/usr/share/${PN}" \
+		MANDIR="/usr/share/man"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		PREFIX="/usr" \
+		DATADIR="/usr/share/${PN}" \
+		MANDIR="/usr/share/man" \
+		install
+
+	if ! use portaudio ; then
+		rm -rf "${D}/usr/share" || die
+	fi
+
+	dodoc README AUTHORS changelog.txt AAA_HOW_TO_MAKE_NEW_LEVELS.txt
+	newicon icons/wordwarvi_icon_128x128.png ${PN}.png
+	make_desktop_entry ${PN} "Word War vi"
+}
-- 
cgit v1.2.3