From 162945d2a91899b637bbb9e163b406350de12906 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 30 Oct 2021 19:43:03 +0100
Subject: gentoo resync : 30.10.2021

---
 games-action/supertuxkart/supertuxkart-1.3.ebuild | 90 +++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 games-action/supertuxkart/supertuxkart-1.3.ebuild

(limited to 'games-action/supertuxkart/supertuxkart-1.3.ebuild')

diff --git a/games-action/supertuxkart/supertuxkart-1.3.ebuild b/games-action/supertuxkart/supertuxkart-1.3.ebuild
new file mode 100644
index 000000000000..59bc12a50831
--- /dev/null
+++ b/games-action/supertuxkart/supertuxkart-1.3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop xdg
+
+MY_P="SuperTuxKart-${PV}-src"
+DESCRIPTION="A kart racing game starring Tux, the linux penguin (TuxKart fork)"
+HOMEPAGE="https://supertuxkart.net/"
+SRC_URI="https://github.com/${PN}/stk-code/releases/download/${PV}/${MY_P}.tar.xz
+	mirror://gentoo/${PN}.png"
+
+LICENSE="GPL-2 GPL-3 CC-BY-SA-3.0 CC-BY-SA-4.0 CC0-1.0 public-domain ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="debug nettle recorder sqlite wiimote"
+
+# don't unbundle irrlicht and bullet
+# both are modified and system versions will break the game
+# https://sourceforge.net/p/irrlicht/feature-requests/138/
+
+RDEPEND="
+	dev-cpp/libmcpp
+	sqlite? ( dev-db/sqlite:3 )
+	dev-libs/angelscript:=
+	media-libs/freetype:2
+	media-libs/glew:0=
+	media-libs/harfbuzz:=
+	media-libs/libpng:0=
+	media-libs/libsdl2
+	media-libs/libvorbis
+	media-libs/openal
+	net-libs/enet:1.3=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/glu
+	virtual/jpeg:0
+	virtual/libintl
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXxf86vm
+	nettle? ( dev-libs/nettle:= )
+	!nettle? (
+		>=dev-libs/openssl-1.0.1d:0=
+	)
+	recorder? ( media-libs/libopenglrecorder )
+	wiimote? ( net-wireless/bluez )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-irrlicht-arch-support.patch
+	"${FILESDIR}"/${PN}-1.3-irrlicht-system-libs.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SQLITE3=$(usex sqlite)
+		-DUSE_SYSTEM_ANGELSCRIPT=ON
+		-DUSE_SYSTEM_ENET=ON
+		-DUSE_SYSTEM_GLEW=ON
+		-DUSE_SYSTEM_SQUISH=OFF
+		-DUSE_SYSTEM_WIIUSE=OFF
+		-DUSE_IPV6=OFF # not supported by system enet
+		-DOpenGL_GL_PREFERENCE=GLVND
+		-DUSE_CRYPTO_OPENSSL=$(usex nettle no yes)
+		-DBUILD_RECORDER=$(usex recorder)
+		-DUSE_WIIUSE=$(usex wiimote)
+		-DSTK_INSTALL_BINARY_DIR=bin
+		-DSTK_INSTALL_DATA_DIR=share/${PN}
+		-DBUILD_SHARED_LIBS=OFF # build bundled libsquish as static library
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dodoc CHANGELOG.md
+
+	doicon -s 64 "${DISTDIR}"/${PN}.png
+}
-- 
cgit v1.2.3