From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 .../hotline-miami-1.0.9a_p20140221-r3.ebuild       | 86 ++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100644 games-action/hotline-miami/hotline-miami-1.0.9a_p20140221-r3.ebuild

(limited to 'games-action/hotline-miami/hotline-miami-1.0.9a_p20140221-r3.ebuild')

diff --git a/games-action/hotline-miami/hotline-miami-1.0.9a_p20140221-r3.ebuild b/games-action/hotline-miami/hotline-miami-1.0.9a_p20140221-r3.ebuild
new file mode 100644
index 000000000000..a997d210ab6d
--- /dev/null
+++ b/games-action/hotline-miami/hotline-miami-1.0.9a_p20140221-r3.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop wrapper
+
+DESCRIPTION="High-octane action game overflowing with raw brutality"
+HOMEPAGE="http://www.devolverdigital.com/games/view/hotline-miami"
+SRC_URI="HotlineMiami_linux_1392944501.tar.gz"
+S="${WORKDIR}"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bundled-libs +launcher"
+RESTRICT="bindist fetch splitdebug"
+
+MYGAMEDIR=/opt/${PN}
+QA_PREBUILT="
+	${MYGAMEDIR#/}/lib/*
+	${MYGAMEDIR#/}/Hotline
+	${MYGAMEDIR#/}/hotline_launcher
+"
+
+# TODO: unbundle Qt5
+RDEPEND="
+	amd64? (
+		>=x11-libs/libX11-1.6.2[abi_x86_32(-)]
+		!bundled-libs? (
+			>=media-gfx/nvidia-cg-toolkit-3.1.0013-r3[abi_x86_32(-)]
+			>=media-libs/libogg-1.3.0[abi_x86_32(-)]
+			>=media-libs/libvorbis-1.3.3-r1[abi_x86_32(-)]
+			>=media-libs/openal-1.15.1[abi_x86_32(-)]
+		)
+		launcher? (
+			>=media-libs/freetype-2.5.0.1[abi_x86_32(-)]
+			>=x11-libs/libXext-1.3.2[abi_x86_32(-)]
+			>=x11-libs/libXrandr-1.4.2[abi_x86_32(-)]
+			>=x11-libs/libXrender-0.9.8[abi_x86_32(-)]
+			>=x11-libs/libxcb-1.9.1[abi_x86_32(-)]
+		)
+	)
+	x86? (
+		x11-libs/libX11
+		!bundled-libs? (
+			media-gfx/nvidia-cg-toolkit
+			media-libs/libogg
+			media-libs/libvorbis
+			media-libs/openal
+		)
+		launcher? (
+			media-libs/freetype
+			x11-libs/libXext
+			x11-libs/libXrandr
+			x11-libs/libXrender
+			x11-libs/libxcb
+		)
+	)
+"
+
+pkg_nofetch() {
+	einfo "Please buy & download ${SRC_URI} from:"
+	einfo "  https://www.humblebundle.com/store"
+	einfo "and move it to your DISTDIR directory."
+}
+
+src_install() {
+	insinto "${MYGAMEDIR}"
+	doins HotlineMiami_GL.wad *.ogg
+
+	exeinto "${MYGAMEDIR}"
+	doexe Hotline
+	use launcher && doexe hotline_launcher
+
+	exeinto "${MYGAMEDIR}/lib"
+	use launcher && doexe lib/libQt5*
+	use bundled-libs && doexe libCg* libopenal*
+
+	make_wrapper ${PN} "./Hotline" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
+	make_desktop_entry ${PN}
+	if use launcher ; then
+		make_wrapper ${PN}-launcher "./hotline_launcher" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
+		make_desktop_entry ${PN}-launcher "${PN} (launcher)"
+	fi
+}
-- 
cgit v1.2.3