From 1798c4aeca70ac8d0a243684d6a798fbc65735f8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 20:57:42 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild | 80 --------------------------
 1 file changed, 80 deletions(-)
 delete mode 100644 dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild

(limited to 'dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild')

diff --git a/dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild b/dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild
deleted file mode 100644
index f638af4de214..000000000000
--- a/dev-vcs/cvsync/cvsync-2014.08.24.014706.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit toolchain-funcs
-
-if [[ ${PV} == "9999" ]] ; then
-	EGIT_REPO_URI="https://github.com/cvsync/cvsync.git"
-	inherit git-r3
-else
-	SRC_URI="mirror://gentoo/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
-	S="${WORKDIR}/${PN}"
-fi
-
-DESCRIPTION="portable CVS repository synchronization utility"
-HOMEPAGE="https://github.com/cvsync/cvsync"
-
-LICENSE="BSD"
-SLOT="0"
-IUSE="gcrypt mhash +openssl"
-REQUIRED_USE="!openssl? ( ^^ ( gcrypt mhash ) )"
-
-RDEPEND="sys-libs/zlib
-	openssl? ( dev-libs/openssl:0= )
-	!openssl? (
-		gcrypt? ( dev-libs/libgcrypt:0= )
-		mhash? ( app-crypt/mhash )
-	)"
-DEPEND="${RDEPEND}"
-
-maint_pkg_create() {
-	cd "${S}"
-	local ver=$(date --date="$(git log -n1 --pretty=format:%ci HEAD)" -u "+%Y.%m.%d.%H%M%S")
-	local tar="${T}/${PN}-${ver}.tar.xz"
-	git archive --prefix "${PN}/" HEAD | xz > "${tar}" || die "creating tar failed"
-	einfo "Packaged tar now available:"
-	einfo "$(du -b "${tar}")"
-}
-
-src_unpack() {
-	if [[ ${PV} == "9999" ]] ; then
-		git-r3_src_unpack
-		maint_pkg_create
-	else
-		default
-	fi
-}
-
-_emake() {
-	# USE flag settings are enforced by REQUIRED_USE.
-	local hash=$(usex openssl openssl $(usex gcrypt gcrypt mhash))
-
-	# Probably want to expand this at some point.
-	local host_os="Linux"
-
-	emake \
-		CC="$(tc-getCC)" \
-		ECHO="echo" \
-		TEST="test" \
-		INSTALL="install" \
-		HASH_TYPE="${hash}" \
-		HOST_OS="${host_os}" \
-		BINOWN="$(id -u)" \
-		BINGRP="$(id -g)" \
-		BINDIR="\$(PREFIX)/usr/bin" \
-		MANDIR="\$(PREFIX)/usr/share/man" \
-		"$@"
-}
-
-src_compile() {
-	_emake PREFIX="${EPREFIX}"
-}
-
-src_install() {
-	dodir /usr/bin /usr/share/man/man1
-	_emake PREFIX="${ED}" install
-	dodoc samples/*.conf
-}
-- 
cgit v1.2.3