From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 .../xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild    | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild

(limited to 'dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild')

diff --git a/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild b/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild
new file mode 100644
index 000000000000..ead20c6c3297
--- /dev/null
+++ b/dev-util/xxdiff/xxdiff-4.0_beta1_p20110426-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils qt4-r2
+
+DESCRIPTION="A graphical file and directories comparator and merge tool"
+HOMEPAGE="http://furius.ca/xxdiff/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+RDEPEND="dev-qt/qtgui:4"
+DEPEND="${RDEPEND}
+	virtual/yacc"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-gcc47.patch \
+		"${FILESDIR}"/${P}-bison3.patch
+
+	pushd src >/dev/null
+	sed -i -e '/qPixmapFromMimeSource/d' *.ui || die #365019
+	qt4-r2_src_prepare
+	popd
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	pushd src >/dev/null
+	qt4-r2_src_configure
+	cat Makefile.extra >> Makefile
+	popd
+
+	distutils-r1_src_configure
+}
+
+src_compile() {
+	pushd src >/dev/null
+	qt4-r2_src_compile
+	popd
+
+	distutils-r1_src_compile
+}
+
+src_install() {
+	dobin bin/xxdiff
+
+	distutils-r1_src_install
+
+	dodoc CHANGES README* TODO doc/*.txt src/doc.txt
+
+	dohtml doc/*.{png,html} src/doc.html
+
+	# example tools, use these to build your own ones
+	insinto /usr/share/doc/${PF}
+	doins -r tools
+}
-- 
cgit v1.2.3