From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 dev-util/shards/shards-0.15.0-r1.ebuild | 47 +++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-util/shards/shards-0.15.0-r1.ebuild

(limited to 'dev-util/shards/shards-0.15.0-r1.ebuild')

diff --git a/dev-util/shards/shards-0.15.0-r1.ebuild b/dev-util/shards/shards-0.15.0-r1.ebuild
new file mode 100644
index 000000000000..cd40186df456
--- /dev/null
+++ b/dev-util/shards/shards-0.15.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multiprocessing toolchain-funcs
+
+CRYSTAL_MOLINILLO_PV=0.2.0
+CRYSTAL_MOLINILLO_P=crystal-molinillo-${CRYSTAL_MOLINILLO_PV}
+
+DESCRIPTION="Dependency manager for the Crystal language"
+HOMEPAGE="https://github.com/crystal-lang/shards"
+SRC_URI="
+	https://github.com/crystal-lang/shards/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/crystal-lang/crystal-molinillo/archive/v${CRYSTAL_MOLINILLO_PV}.tar.gz -> ${CRYSTAL_MOLINILLO_P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>dev-lang/crystal-0.11.1
+	dev-libs/libyaml
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT=test # missing files in tarball
+
+src_prepare() {
+	default
+
+	# bundle crystal-molinillo to bootstrap 'shards'
+	mkdir -p lib || die
+	ln -s ../../${CRYSTAL_MOLINILLO_P} lib/molinillo || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake release=1 FLAGS="--link-flags=\"${LDFLAGS}\" --verbose --threads $(makeopts_jobs)"
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc README.md
+}
-- 
cgit v1.2.3