From 14a74a5f982f25582974c2ee235027a041aec36d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 25 Nov 2022 07:12:05 +0000
Subject: gentoo auto-resync : 25:11:2022 - 07:12:04

---
 dev-util/rats/rats-2.4-r2.ebuild | 43 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-util/rats/rats-2.4-r2.ebuild

(limited to 'dev-util/rats/rats-2.4-r2.ebuild')

diff --git a/dev-util/rats/rats-2.4-r2.ebuild b/dev-util/rats/rats-2.4-r2.ebuild
new file mode 100644
index 000000000000..6e50805b79bd
--- /dev/null
+++ b/dev-util/rats/rats-2.4-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools edos2unix
+
+DESCRIPTION="RATS - Rough Auditing Tool for Security"
+HOMEPAGE="https://github.com/andrew-d/rough-auditing-tool-for-security"
+# No tags available in the GitHub port
+SRC_URI="https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/rough-auditing-tool-for-security/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+RDEPEND="dev-libs/expat:="
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.4-fix-build-system.patch )
+
+src_prepare() {
+	default
+
+	local f
+	while IFS="" read -d $'\0' -r f; do
+		einfo "Converting ${f} from CRLF to LF"
+		edos2unix "${f}"
+	done < <(find \( -name '*.[chl]' -o -name '*.in' -o -name '*.am' \) -print0)
+
+	# Clang 16
+	eautoreconf
+}
+
+src_configure() {
+	econf --datadir="${EPREFIX}/usr/share/${PN}/"
+}
+
+pkg_postinst() {
+	ewarn "Please be careful when using this program with it's force language"
+	ewarn "option, '--language <LANG>' it may take huge amounts of memory when"
+	ewarn "it tries to treat binary files as some other type."
+}
-- 
cgit v1.2.3