From 080a6ad2c3759083c02506e1348b689f2194d4eb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 29 Feb 2024 11:41:17 +0000
Subject: gentoo auto-resync : 29:02:2024 - 11:41:17

---
 dev-util/ragel/ragel-7.0.4.ebuild | 65 ---------------------------------------
 1 file changed, 65 deletions(-)
 delete mode 100644 dev-util/ragel/ragel-7.0.4.ebuild

(limited to 'dev-util/ragel/ragel-7.0.4.ebuild')

diff --git a/dev-util/ragel/ragel-7.0.4.ebuild b/dev-util/ragel/ragel-7.0.4.ebuild
deleted file mode 100644
index 00d0e8a15df2..000000000000
--- a/dev-util/ragel/ragel-7.0.4.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools
-
-DESCRIPTION="Compiles finite state machines from regular languages into executable code"
-HOMEPAGE="https://www.colm.net/open-source/ragel/"
-SRC_URI="https://www.colm.net/files/ragel/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="doc"
-
-# Notes from bug #766090
-# dev-libs/libxml2's xmllint ends up being called by asciidoc here
-# app-text/dblatex too
-# app-text/ghostscript-gpl too
-BDEPEND="
-	doc? (
-		|| ( app-text/asciidoc dev-ruby/asciidoctor )
-		app-text/dblatex
-		app-text/ghostscript-gpl
-		dev-libs/libxml2
-		dev-texlive/texlive-latex
-		dev-python/pygments
-		media-gfx/transfig
-	)
-"
-DEPEND="~dev-util/colm-0.14.7"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-7.0.4-drop-julia-check.patch
-)
-
-src_prepare() {
-	default
-
-	# Fix hardcoded search dir
-	sed -i -e "s:\$withval/lib:\$withval/$(get_libdir):" configure.ac || die
-
-	# Allow either asciidoctor or asciidoc
-	# bug #733426
-	sed -i -e 's/(\[ASCIIDOC\], \[asciidoc\], \[asciidoc\]/S([ASCIIDOC], [asciidoc asciidoctor]/' configure.ac || die
-
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--with-colm="${EPREFIX}/usr" \
-		$(use_enable doc manual)
-}
-
-src_install() {
-	default
-
-	insinto /usr/share/vim/vimfiles/syntax
-	doins ragel.vim
-
-	find "${ED}" -name '*.la' -delete || die
-}
-- 
cgit v1.2.3