From 423d21dcfee183cc4b04d29c1621615e8c30f834 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 4 Jan 2018 18:55:01 +0000
Subject: gentoo resync : 04.01.2018

---
 dev-util/lldb/Manifest             |   1 +
 dev-util/lldb/lldb-6.0.9999.ebuild | 122 +++++++++++++++++++++++++++++++++++++
 2 files changed, 123 insertions(+)
 create mode 100644 dev-util/lldb/lldb-6.0.9999.ebuild

(limited to 'dev-util/lldb')

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index 3051b0476ca3..8ecac99af15e 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -9,5 +9,6 @@ DIST llvm-5.0.1.src.tar.xz 23428720 BLAKE2B 3db4d33df21018d17eef0042c0d8d82a8412
 EBUILD lldb-4.0.1.ebuild 3061 BLAKE2B 8d46c18a5518403e73e40e38ecfafb6dffe59ac554c04dcfd92020a932c3a4a32cfc5dd19de649b1fd0d9c4cac4c2d70ede3bb0472adf3814259fc39389533dc SHA512 d88dc965435cddf490e5fb7ba36ecb43cdc3c4ecf5865d531f3141f40226bba0cc63ff604d62e8e1d436da2c48c4f5a435e0561f265b0e2961423770e9edc43a
 EBUILD lldb-5.0.0.ebuild 2811 BLAKE2B f8a5c12fe179486993f4ed0da5f4b6abb4e282c4c5702277af7853cb71b4cacd1fa998346d07373fdc0e5f051155c373e2c5cfc30131afbf08660a782ac7b81d SHA512 e4b38ef25db0a8b764bc7b1540190024557ddafcae6613d3c55fb98b67ca72a922b5224b8f65144050cc3055418bbde6769ae30bd90cb5d30083c018e1fee8f4
 EBUILD lldb-5.0.1.ebuild 3067 BLAKE2B 790a43c29244d006a3bf9ac3c8548f9348a2d18b96aecc156cef76d3145dbc34d22aa6534d8338d23e79113bf1a6d87c00464427aae5ee6b1c513d8fd2985e54 SHA512 41807a680175c6c836ef852b58f4306c32a21111da4b78c6584696a68e9424cb2de27bd2394164ac1cc91bcdf759a5fd0112d137bed9c9714ff60e66af9bd29d
+EBUILD lldb-6.0.9999.ebuild 3086 BLAKE2B a569f675b0a1da11c6cc663de56e2227a2c0a38ff01e69b0eb258655d6a7a1ed2d15ff5da9274f0fc3750a9ec3e07b8a6be4a8c07fbe004b36682944637a43f2 SHA512 ade71218d5aabd59cc5fdd7f8f39b69af49ee5be79abe7105c74b23d3abdb1c9a3c15fc09735111e31dfcf50013f00b985ebff89487c11e99129fa7cd81c8d7b
 EBUILD lldb-9999.ebuild 3061 BLAKE2B fc4cdb38222831d0e0f9fe93b44306160b56eeb1b23d1015dbfc5761fdfbd22f0deed91d420870469dc0e9fd777be8cf9ade79e3eb90f275a3e0e18205aa97f4 SHA512 facc16f2f3ab686f2247d833c9f4a12ab6c0ad2e70d72452d6d96234a5f6f66106ccd16175065dd6e6405ed014ef9e687494a877fe7eeaa3a64ac9cdaa292fb5
 MISC metadata.xml 216 BLAKE2B fe5e49887842aa513fbf1f2e09bed09a884d531fd21bdaeb2d389e8bf590b6c0e7063f0af98f66e2db129308ab0f0804ba327c3c752bbb4c900c59ac109d99aa SHA512 3485598147c953e72e1785693a489a7e7d73d59620b76054db9c0ce95d8bfa0e8ffec29da7f7a9d73a32e5b77eac07ca3306c56a972dc57fd89d477edaebf3d5
diff --git a/dev-util/lldb/lldb-6.0.9999.ebuild b/dev-util/lldb/lldb-6.0.9999.ebuild
new file mode 100644
index 000000000000..002f1571b638
--- /dev/null
+++ b/dev-util/lldb/lldb-6.0.9999.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils git-r3 llvm python-single-r1 toolchain-funcs
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://git.llvm.org/git/lldb.git
+	https://github.com/llvm-mirror/lldb.git"
+EGIT_BRANCH="release_60"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="libedit ncurses python test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? ( dev-python/six[${PYTHON_USEDEP}]
+		${PYTHON_DEPS} )
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+# swig-3.0.9+ generates invalid wrappers, #598708
+# upstream: https://github.com/swig/swig/issues/769
+DEPEND="${RDEPEND}
+	python? ( <dev-lang/swig-3.0.9 )
+	test? ( ~dev-python/lit-${PV}[${PYTHON_USEDEP}] )
+	${PYTHON_DEPS}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if use test; then
+		# needed for patched gtest
+		git-r3_fetch "https://git.llvm.org/git/llvm.git
+			https://github.com/llvm-mirror/llvm.git"
+	fi
+	git-r3_fetch
+
+	if use test; then
+		git-r3_checkout https://llvm.org/git/llvm.git \
+			"${WORKDIR}"/llvm '' lib/Testing/Support utils/unittest
+	fi
+	git-r3_checkout
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_DISABLE_CURSES=$(usex !ncurses)
+		-DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
+		-DLLDB_DISABLE_PYTHON=$(usex !python)
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+		-DLLVM_BUILD_TESTS=$(usex test)
+		# compilers for lit tests
+		-DLLDB_TEST_C_COMPILER="$(type -P clang)"
+		-DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
+		# compiler for ole' python tests
+		-DLLDB_TEST_COMPILER="$(type -P clang)"
+
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="-vv"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cmake-utils_src_make check-lldb-lit
+	use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# oh my...
+	if use python; then
+		# remove bundled six module
+		rm "${D}$(python_get_sitedir)/six.py" || die
+
+		# remove custom readline.so for now
+		# TODO: figure out how to deal with it
+		# upstream is basically building a custom readline.so with -ledit
+		# to avoid symbol collisions between readline and libedit...
+		rm "${D}$(python_get_sitedir)/readline.so" || die
+
+		# byte-compile the modules
+		python_optimize
+	fi
+}
-- 
cgit v1.2.3