From 5bb9ff1ee56d2b5e75e01a7f066d8b0cec84ec02 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 20 Mar 2021 14:27:17 +0000
Subject: gentoo resync : 20.03.2021

---
 dev-util/libabigail/libabigail-1.8.2.ebuild | 77 +++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 dev-util/libabigail/libabigail-1.8.2.ebuild

(limited to 'dev-util/libabigail/libabigail-1.8.2.ebuild')

diff --git a/dev-util/libabigail/libabigail-1.8.2.ebuild b/dev-util/libabigail/libabigail-1.8.2.ebuild
new file mode 100644
index 000000000000..65225b855535
--- /dev/null
+++ b/dev-util/libabigail/libabigail-1.8.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit autotools python-any-r1 out-of-source
+
+DESCRIPTION="Suite of tools for checking ABI differences between ELF objects"
+HOMEPAGE="https://sourceware.org/libabigail/"
+SRC_URI="https://mirrors.kernel.org/sourceware/libabigail/${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/elfutils:=
+	dev-libs/libxml2:2="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		sys-apps/texinfo
+	)
+	test? ( ${PYTHON_DEPS} )"
+
+src_prepare() {
+	default
+	# need to run our autotools, due to ltmain.sh including Redhat calls:
+	# cannot read spec file '/usr/lib/rpm/redhat/redhat-hardened-ld': No such file or directory
+	eautoreconf
+}
+
+my_src_configure() {
+	econf \
+		--disable-deb \
+		--disable-fedabipkgdiff \
+		--disable-rpm \
+		--disable-static \
+		--disable-zip-archive \
+		--enable-bash-completion \
+		--enable-cxx11 \
+		--enable-python3 \
+		$(use_enable doc apidoc) \
+		$(use_enable doc manual)
+}
+
+my_src_compile() {
+	default
+	use doc && emake doc
+}
+
+my_src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		doman doc/manuals/man/*
+		doinfo doc/manuals/texinfo/abigail.info
+
+		dodoc -r doc/manuals/html
+
+		docinto html/api
+		dodoc -r doc/api/html/.
+	fi
+}
+
+my_src_install_all() {
+	einstalldocs
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3