From 3cf7c3ef441822c889356fd1812ebf2944a59851 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 25 Aug 2020 10:45:55 +0100
Subject: gentoo resync : 25.08.2020

---
 dev-util/kbuild/kbuild-0.1.9998.3407.ebuild | 71 +++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 dev-util/kbuild/kbuild-0.1.9998.3407.ebuild

(limited to 'dev-util/kbuild/kbuild-0.1.9998.3407.ebuild')

diff --git a/dev-util/kbuild/kbuild-0.1.9998.3407.ebuild b/dev-util/kbuild/kbuild-0.1.9998.3407.ebuild
new file mode 100644
index 000000000000..3c367b7ff0cd
--- /dev/null
+++ b/dev-util/kbuild/kbuild-0.1.9998.3407.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs
+
+MY_P="${P}-src"
+DESCRIPTION="A makefile framework for writing simple makefiles for complex tasks"
+HOMEPAGE="http://svn.netlabs.org/kbuild/wiki"
+#SRC_URI="ftp://ftp.netlabs.org/pub/${PN}/${MY_P}.tar.gz"
+SRC_URI="https://dev.gentoo.org/~polynomial-c/${MY_P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# We cannot depend on virtual/yacc until bug #734354 has been fixed
+DEPEND="
+	sys-apps/texinfo
+	sys-devel/flex
+	sys-devel/gettext
+	|| (
+		dev-util/byacc
+		dev-util/yacc
+		<sys-devel/bison-3.7
+	)
+"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.1.9998.3407-unknown_configure_opt.patch"
+	"${FILESDIR}/${PN}-0.1.5-gentoo-docdir.patch"
+	"${FILESDIR}/${PN}-0.1.9998_pre20120806-qa.patch"
+	"${FILESDIR}/${PN}-0.1.9998_pre20110817-kash-link-pthread.patch"
+	"${FILESDIR}/${PN}-0.1.9998.3407-gold.patch"
+	"${FILESDIR}/${PN}-0.1.9998.3407-glibc-2.32+.patch"
+)
+
+pkg_setup() {
+	# Package fails with distcc (bug #255371)
+	export DISTCC_DISABLE=1
+}
+
+src_prepare() {
+	default
+
+	# Add a file with the svn revision this package was pulled from
+	printf '%s\n' "KBUILD_SVN_REV := $(ver_cut 4)" \
+		> SvnInfo.kmk || die
+
+	cd "${S}/src/kmk" || die
+	eautoreconf
+	cd "${S}/src/sed" || die
+	eautoreconf
+
+	sed -e "s@_LDFLAGS\.$(tc-arch)*.*=@& ${LDFLAGS}@g" \
+		-i "${S}"/Config.kmk || die #332225
+	tc-export CC PKG_CONFIG RANLIB #AR does not work here
+}
+
+src_compile() {
+	kBuild/env.sh --full emake -f bootstrap.gmk AUTORECONF=true AR="$(tc-getAR)" \
+		|| die "bootstrap failed"
+}
+
+src_install() {
+	kBuild/env.sh kmk NIX_INSTALL_DIR=/usr PATH_INS="${D}" install \
+		|| die "install failed"
+}
-- 
cgit v1.2.3