From 463397cf1e064185110fe57c568d73f99a06f5d1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 17 Feb 2021 10:35:54 +0000
Subject: gentoo resync : 17.02.2021

---
 dev-util/hermes/hermes-9999.ebuild | 55 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-util/hermes/hermes-9999.ebuild

(limited to 'dev-util/hermes/hermes-9999.ebuild')

diff --git a/dev-util/hermes/hermes-9999.ebuild b/dev-util/hermes/hermes-9999.ebuild
new file mode 100644
index 000000000000..e616c7382f47
--- /dev/null
+++ b/dev-util/hermes/hermes-9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+inherit lua-single
+
+DESCRIPTION="Lua based testing manager"
+HOMEPAGE="https://github.com/TACC/Hermes"
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/TACC/Hermes"
+else
+	COMMIT="b99622087233178368cff6cf38ec72fa01dfd8a6"
+	SRC_URI="https://github.com/TACC/Hermes/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/Hermes-${PV}
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}
+	$(lua_gen_cond_dep '
+		dev-lua/luafilesystem[${LUA_USEDEP}]
+		dev-lua/luaposix[${LUA_USEDEP}]
+	')
+"
+DEPEND="test? ( ${RDEPEND} )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.8-lua-shebang.patch )
+
+src_compile() {
+	sed -e "s|@LUA@|${LUA}|g" \
+		-i lib/tool.lua \
+		-i bin/lua_cmd || die
+}
+
+src_test() {
+	local -x PATH="bin:${PATH}"
+	tm -vvv || die
+	testcleanup || die
+}
+
+src_install() {
+	dodir /opt/hermes
+	cp -r "${S}"/. "${ED}"/opt/hermes/ || die
+
+	doenvd "${FILESDIR}"/99hermes
+}
-- 
cgit v1.2.3