From 463397cf1e064185110fe57c568d73f99a06f5d1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 17 Feb 2021 10:35:54 +0000
Subject: gentoo resync : 17.02.2021

---
 dev-util/gtk-doc/Manifest                 |   1 +
 dev-util/gtk-doc/gtk-doc-1.33.1-r4.ebuild | 110 ++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)
 create mode 100644 dev-util/gtk-doc/gtk-doc-1.33.1-r4.ebuild

(limited to 'dev-util/gtk-doc')

diff --git a/dev-util/gtk-doc/Manifest b/dev-util/gtk-doc/Manifest
index bef1ad2d59ac..aaeadee14616 100644
--- a/dev-util/gtk-doc/Manifest
+++ b/dev-util/gtk-doc/Manifest
@@ -6,4 +6,5 @@ DIST gtk-doc-1.33.1.tar.xz 768896 BLAKE2B 0d6cc32611618669aac4045942497a404f4d3e
 EBUILD gtk-doc-1.32-r1.ebuild 2325 BLAKE2B ac9e1061f3fcec7cfc6cc90746e4444259dad4e705817a459e9735a2691f7e4d80701d9a688f3b9ad773429e0248491661a526e798318025022f75a997824cd6 SHA512 f9a4eaafff2b0edf6f6d0b13a5b82db0d19a36cf3d1ed2b1872787bb5ee1369f0a75300f59db8dfab7b54a0a15cecfd16215c221ffc0039985476ec20cd362ce
 EBUILD gtk-doc-1.32-r2.ebuild 2549 BLAKE2B e1fe420648742f9c9300522fe262d105411fe29d7bcc67d8ab17ef7be7e7553ca0e52a5c079c392c9f7f6833970426993df091c1b0a3ff46528d7b5eeec57b87 SHA512 38f4b9bdf9f9274a00d9fddedd827c66f4709a63441b097a306faf95d6b8e0a9b7efceb237e31f9a60821426a9d54fcb4d131763793ce5580fe70d8360f77cfa
 EBUILD gtk-doc-1.33.1-r3.ebuild 2568 BLAKE2B b91e838e58259c1198963e66337b2cbe8d2b1261c2d9e1c8b384733aa4b9d6f4b57887cb00c9e999f40573b9ef6f1b358551e2d588794a9f16d035eb9c4196b0 SHA512 1391ab5c8dc72747aef6ab0db001e44306eff25fd129b32163c2165b8703b7c55bd8b025568b7d7a8a550132c51d25b7c4b96024b3a087a734f7274b8ef15046
+EBUILD gtk-doc-1.33.1-r4.ebuild 2619 BLAKE2B 2edc191c2c894bc54fe0422a97d2dd11f2fd7b7923f66b330f2ea3208029aee1a0fa1be433572ca9b9a0d90cbf22e9c1cc8cc5cb87170dfb7e5a267015871381 SHA512 d4c65af4234bf660336a5b6eed024e1b9fa486b570fd67d34fb6c3b0ec39d606289f54507818c3b62c3d16f3156a51151a5180c899e40350fb85dc343640664d
 MISC metadata.xml 490 BLAKE2B 9b4d27b146f567501af858fd704d7713e8eea66caac0b5878d685814b48825f4222a6286acd3a8ec4d8e698ace318c52c74e301dc8eb3eec41bca3d83d24a130 SHA512 0d33e970b5924c264711c8a77aa966ff8f1e6cd2695d34088c0f9af825cd72603173e07e39fb6d6bd22098d76c048b3dc03dd83916b092f2c68c58f94aa95b7a
diff --git a/dev-util/gtk-doc/gtk-doc-1.33.1-r4.ebuild b/dev-util/gtk-doc/gtk-doc-1.33.1-r4.ebuild
new file mode 100644
index 000000000000..5f9d0375b60b
--- /dev/null
+++ b/dev-util/gtk-doc/gtk-doc-1.33.1-r4.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit elisp-common gnome.org meson python-single-r1 readme.gentoo-r1
+
+DESCRIPTION="GTK+ Documentation Generator"
+HOMEPAGE="https://wiki.gnome.org/DocumentationProject/GtkDoc"
+
+LICENSE="GPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ppc64 ~riscv ~s390 sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x64-solaris"
+
+IUSE="emacs test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.38:2
+	dev-libs/libxslt
+	>=dev-libs/libxml2-2.3.6:2
+	~app-text/docbook-xml-dtd-4.3
+	app-text/docbook-xsl-stylesheets
+	~app-text/docbook-sgml-dtd-3.0
+	>=app-text/docbook-dsssl-stylesheets-1.40
+	emacs? ( >=app-editors/emacs-23.1:* )
+	$(python_gen_cond_dep '
+		dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/parameterized[${PYTHON_USEDEP}]
+		')
+	)
+"
+BDEPEND="
+	~dev-util/gtk-doc-am-${PV}
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Remove global Emacs keybindings, bug #184588
+	"${FILESDIR}"/${PN}-1.8-emacs-keybindings.patch
+)
+
+pkg_setup() {
+	DOC_CONTENTS="gtk-doc does no longer define global key bindings for Emacs.
+		You may set your own key bindings for \"gtk-doc-insert\" and
+		\"gtk-doc-insert-section\" in your ~/.emacs file."
+	SITEFILE=61${PN}-gentoo.el
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Requires the unpackaged Python "anytree" module
+	sed -i -e '/mkhtml2/d' "${S}"/tests/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dautotools_support=true
+		-Dcmake_support=true
+		-Dyelp_manual=true
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	use emacs && elisp-compile tools/gtk-doc.el
+}
+
+src_install() {
+	meson_src_install
+
+	# The meson build system configures the shebangs to the temporary python
+	# used during the build. We need to fix it.
+	sed -i -e 's:^#!.*python3:#!/usr/bin/env python3:' "${ED}"/usr/bin/* || die
+	python_fix_shebang "${ED}"/usr/bin
+
+	# Don't install this file, it's in gtk-doc-am now
+	rm "${ED}"/usr/share/aclocal/gtk-doc.m4 || die "failed to remove gtk-doc.m4"
+	rmdir "${ED}"/usr/share/aclocal || die
+
+	if use emacs; then
+		elisp-install ${PN} tools/gtk-doc.el*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		readme.gentoo_create_doc
+	fi
+}
+
+pkg_postinst() {
+	if use emacs; then
+		elisp-site-regen
+		readme.gentoo_print_elog
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3