From 0706fc6986773f4e4d391deff4ad5143c464ea4e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 24 Mar 2019 17:44:59 +0000
Subject: Revert "gentoo resync : 24.03.2019"

This reverts commit aa3411e241a201d53a2689766fe419f2756819f3.
---
 dev-util/gn/gn-0.1479.ebuild | 64 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-util/gn/gn-0.1479.ebuild

(limited to 'dev-util/gn/gn-0.1479.ebuild')

diff --git a/dev-util/gn/gn-0.1479.ebuild b/dev-util/gn/gn-0.1479.ebuild
new file mode 100644
index 000000000000..89fd565c9595
--- /dev/null
+++ b/dev-util/gn/gn-0.1479.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+
+inherit ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+SRC_URI="https://dev.gentoo.org/~floppym/dist/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="vim-syntax"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r2.patch
+	"${FILESDIR}"/gn-numerics-arm.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-sysroot --no-last-commit-position
+	echo "$@"
+	"$@" || die
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	if use vim-syntax; then
+		insinto /usr/share/vim/vimfiles
+		doins -r tools/gn/misc/vim/{autoload,ftdetect,ftplugin,syntax}
+	fi
+}
-- 
cgit v1.2.3