From 623ee73d661e5ed8475cb264511f683407d87365 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 12 Apr 2020 03:41:30 +0100
Subject: gentoo Easter resync : 12.04.2020

---
 dev-util/dialog/dialog-1.3.20200228.ebuild | 49 ++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-util/dialog/dialog-1.3.20200228.ebuild

(limited to 'dev-util/dialog/dialog-1.3.20200228.ebuild')

diff --git a/dev-util/dialog/dialog-1.3.20200228.ebuild b/dev-util/dialog/dialog-1.3.20200228.ebuild
new file mode 100644
index 000000000000..7a23e6577d51
--- /dev/null
+++ b/dev-util/dialog/dialog-1.3.20200228.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIA_P=${PN}-$(ver_cut 1-2)-$(ver_cut 3)
+DESCRIPTION="tool to display dialog boxes from a shell"
+HOMEPAGE="https://invisible-island.net/dialog/"
+SRC_URI="https://dev.gentoo.org/~jer/${DIA_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/15"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="examples minimal nls static-libs unicode"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.2-r5:=[unicode?]
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	!minimal? ( sys-devel/libtool )
+"
+S=${WORKDIR}/${DIA_P}
+
+src_prepare() {
+	default
+	sed -i -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' configure || die
+	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-rpath-hack \
+		$(use_enable nls) \
+		$(use_with !minimal libtool) \
+		--with-libtool-opts=$(usex static-libs '' '-shared') \
+		--with-ncurses$(usex unicode w '')
+}
+
+src_install() {
+	use minimal && default || emake DESTDIR="${D}" install-full
+
+	use examples && dodoc -r samples
+
+	dodoc CHANGES README
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3