From 9c417bacd51da6d8b57fa9f37425161d30d4b95b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 28 Nov 2020 20:40:51 +0000
Subject: gentoo resync : 28.11.2020

---
 .../desktop-file-utils-0.26-r1.ebuild              | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-util/desktop-file-utils/desktop-file-utils-0.26-r1.ebuild

(limited to 'dev-util/desktop-file-utils/desktop-file-utils-0.26-r1.ebuild')

diff --git a/dev-util/desktop-file-utils/desktop-file-utils-0.26-r1.ebuild b/dev-util/desktop-file-utils/desktop-file-utils-0.26-r1.ebuild
new file mode 100644
index 000000000000..52a6baaa91b2
--- /dev/null
+++ b/dev-util/desktop-file-utils/desktop-file-utils-0.26-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit elisp-common meson
+
+DESCRIPTION="Command line utilities to work with desktop menu entries"
+HOMEPAGE="https://freedesktop.org/wiki/Software/desktop-file-utils"
+SRC_URI="https://www.freedesktop.org/software/${PN}/releases/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="emacs"
+
+RDEPEND=">=dev-libs/glib-2.12:2"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README )
+
+src_compile() {
+	meson_src_compile
+	use emacs && elisp-compile misc/desktop-entry-mode.el
+}
+
+src_install() {
+	meson_src_install
+	if use emacs; then
+		elisp-install ${PN} misc/*.el misc/*.elc || die
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3