From dc7cbdfa65fd814b3b9aa3c56257da201109e807 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 5 Apr 2019 21:17:31 +0100
Subject: gentoo resync : 05.04.2019

---
 dev-util/cmocka/cmocka-1.1.5.ebuild | 44 +++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-util/cmocka/cmocka-1.1.5.ebuild

(limited to 'dev-util/cmocka/cmocka-1.1.5.ebuild')

diff --git a/dev-util/cmocka/cmocka-1.1.5.ebuild b/dev-util/cmocka/cmocka-1.1.5.ebuild
new file mode 100644
index 000000000000..e0d5dc6a7262
--- /dev/null
+++ b/dev-util/cmocka/cmocka-1.1.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-multilib
+
+DESCRIPTION="Unit testing framework for C"
+HOMEPAGE="https://cmocka.org/"
+SRC_URI="https://cmocka.org/files/1.1/${P}.tar.xz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc examples static-libs test"
+
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_STATIC_LIB=$(usex static-libs)
+		-DUNIT_TESTING=$(usex test)
+		$(multilib_is_native_abi && cmake-utils_use_find_package doc Doxygen \
+			|| echo -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON)
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+	multilib_is_native_abi && use doc && cmake-utils_src_compile docs
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi && use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
+	fi
+
+	cmake-utils_src_install
+}
-- 
cgit v1.2.3