From 9f51c386724b9543e88a9c0e1be57d44326f3116 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 27 Aug 2023 16:00:10 +0100
Subject: gentoo auto-resync : 27:08:2023 - 16:00:10

---
 dev-util/clippy/clippy-9.0.ebuild | 58 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-util/clippy/clippy-9.0.ebuild

(limited to 'dev-util/clippy/clippy-9.0.ebuild')

diff --git a/dev-util/clippy/clippy-9.0.ebuild b/dev-util/clippy/clippy-9.0.ebuild
new file mode 100644
index 000000000000..5c3fda52b99a
--- /dev/null
+++ b/dev-util/clippy/clippy-9.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="frr-${PV}"
+PYTHON_COMPAT=( python3_{9..11} )
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone clippy tool built from FRR sources"
+HOMEPAGE="https://frrouting.org/"
+SRC_URI="https://github.com/FRRouting/frr/archive/${MY_P}.tar.gz"
+S="${WORKDIR}/frr-${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# standalone clippy does not have any tests
+# restrict to prevent bug 811753
+RESTRICT="test"
+
+DEPEND="
+	${PYTHON_DEPS}
+	virtual/libelf:=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	mallinfo	# check in configure is fallback is needed
+	mallinfo2	# check in configure is fallback is needed
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #884291
+	unset YACC
+	export LEX=flex
+
+	econf --enable-clippy-only
+}
+
+src_install() {
+	# 830087
+	find "lib" -type f -name "clippy" -print0 |
+		xargs -0 file | grep executable | grep ELF | cut -f 1 -d : |
+		xargs -I '{}' dobin '{}' ||
+		die "Failed to install 'lib/clippy'"
+}
-- 
cgit v1.2.3