From 7f6382ebb44b75c53021d4c4ab77d6b34aed21ac Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 4 Apr 2023 11:22:15 +0100
Subject: gentoo auto-resync : 04:04:2023 - 11:22:14

---
 dev-util/clippy/clippy-8.5.ebuild | 53 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-util/clippy/clippy-8.5.ebuild

(limited to 'dev-util/clippy/clippy-8.5.ebuild')

diff --git a/dev-util/clippy/clippy-8.5.ebuild b/dev-util/clippy/clippy-8.5.ebuild
new file mode 100644
index 000000000000..c9bb649db28e
--- /dev/null
+++ b/dev-util/clippy/clippy-8.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="frr-${PV}"
+PYTHON_COMPAT=( python3_{9..11} )
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone clippy tool built from FRR sources"
+HOMEPAGE="https://frrouting.org/"
+SRC_URI="https://github.com/FRRouting/frr/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/frr-${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# standalone clippy does not have any tests
+# restrict to prevent bug 811753
+RESTRICT="test"
+
+DEPEND="
+	${PYTHON_DEPS}
+	virtual/libelf:=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #884291
+	unset YACC
+	export LEX=flex
+
+	econf --enable-clippy-only
+}
+
+src_install() {
+	# 830087
+	find "lib" -type f -name "clippy" -print0 |
+		xargs -0 file | grep executable | grep ELF | cut -f 1 -d : |
+		xargs -I '{}' dobin '{}' ||
+		die "Failed to install 'lib/clippy'"
+}
-- 
cgit v1.2.3