From c8a77dfe4d3d307c1d5dd2650b7297447d8b609d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 12 Jan 2019 16:58:08 +0000
Subject: gentoo resync : 12.01.2019

---
 dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild | 97 ++++++++++++++++++++++++++++
 1 file changed, 97 insertions(+)
 create mode 100644 dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild

(limited to 'dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild')

diff --git a/dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild b/dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild
new file mode 100644
index 000000000000..a431bbafab73
--- /dev/null
+++ b/dev-util/bitcoin-tx/bitcoin-tx-0.17.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools bash-completion-r1
+
+BITCOINCORE_COMMITHASH="ef70f9b52b851c7997a9f1a0834714e3eebc1fd8"
+KNOTS_PV="${PV}.knots20181229"
+KNOTS_P="bitcoin-${KNOTS_PV}"
+
+DESCRIPTION="Command-line Bitcoin transaction tool"
+HOMEPAGE="https://bitcoincore.org/ https://bitcoinknots.org/"
+SRC_URI="
+	https://github.com/bitcoin/bitcoin/archive/${BITCOINCORE_COMMITHASH}.tar.gz -> bitcoin-v${PV}.tar.gz
+	https://bitcoinknots.org/files/0.17.x/${KNOTS_PV}/${KNOTS_P}.patches.txz -> ${KNOTS_P}.patches.tar.xz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="knots libressl"
+
+DEPEND="
+	>=dev-libs/boost-1.52.0:=[threads(+)]
+	>=dev-libs/libsecp256k1-0.0.0_pre20151118:=[recovery]
+	>=dev-libs/univalue-1.0.4:=
+	!libressl? ( dev-libs/openssl:0=[-bindist] )
+	libressl? ( dev-libs/libressl:0= )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( doc/bips.md doc/release-notes.md )
+
+S="${WORKDIR}/bitcoin-${BITCOINCORE_COMMITHASH}"
+
+pkg_pretend() {
+	if use knots; then
+		elog "You are building ${PN} from Bitcoin Knots."
+		elog "For more information, see:"
+		elog "https://bitcoinknots.org/files/0.17.x/${KNOTS_PV}/${KNOTS_P}.desc.html"
+	else
+		elog "You are building ${PN} from Bitcoin Core."
+		elog "For more information, see:"
+		elog "https://bitcoincore.org/en/2018/12/25/release-${PV}/"
+	fi
+}
+
+src_prepare() {
+	local knots_patchdir="${WORKDIR}/${KNOTS_P}.patches/"
+
+	eapply "${knots_patchdir}/${KNOTS_P}.syslibs.patch"
+
+	if use knots; then
+		eapply "${knots_patchdir}/${KNOTS_P}.f.patch"
+		eapply "${knots_patchdir}/${KNOTS_P}.branding.patch"
+		eapply "${knots_patchdir}/${KNOTS_P}.ts.patch"
+	fi
+
+	eapply_user
+
+	echo '#!/bin/true' >share/genbuild.sh || die
+	mkdir -p src/obj || die
+	echo "#define BUILD_SUFFIX gentoo${PVR#${PV}}" >src/obj/build.h || die
+
+	eautoreconf
+	rm -r src/leveldb src/secp256k1 || die
+}
+
+src_configure() {
+	local my_econf=(
+		--disable-asm
+		--without-qtdbus
+		--without-qrencode
+		--without-miniupnpc
+		--disable-tests
+		--disable-wallet
+		--disable-zmq
+		--enable-util-tx
+		--disable-util-cli
+		--disable-bench
+		--without-libs
+		--without-daemon
+		--without-gui
+		--disable-ccache
+		--disable-static
+		--with-system-libsecp256k1
+		--with-system-univalue
+	)
+	econf "${my_econf[@]}"
+}
+
+src_install() {
+	default
+
+	newbashcomp contrib/${PN}.bash-completion ${PN}
+}
-- 
cgit v1.2.3