From 67717f5ed7e33856e34f632d5f17a5e218401c0a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 4 Sep 2022 04:20:30 +0100
Subject: gentoo auto-resync : 04:09:2022 - 04:20:30

---
 dev-util/b2/b2-4.9.2.ebuild | 64 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-util/b2/b2-4.9.2.ebuild

(limited to 'dev-util/b2/b2-4.9.2.ebuild')

diff --git a/dev-util/b2/b2-4.9.2.ebuild b/dev-util/b2/b2-4.9.2.ebuild
new file mode 100644
index 000000000000..87941672b2d5
--- /dev/null
+++ b/dev-util/b2/b2-4.9.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+MY_PV="$(ver_rs 1- _)"
+
+DESCRIPTION="A system for large project software construction, simple to use and powerful"
+HOMEPAGE="https://www.bfgroup.xyz/b2/"
+SRC_URI="https://github.com/bfgroup/b2/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P}/src"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="examples"
+RESTRICT="test"
+
+RDEPEND="!dev-util/boost-build"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.9.2-disable_python_rpath.patch
+	"${FILESDIR}"/${PN}-4.9.2-darwin-gentoo-toolchain.patch
+	"${FILESDIR}"/${PN}-4.9.2-add-none-feature-options.patch
+	"${FILESDIR}"/${PN}-4.9.2-respect-user-flags.patch
+	"${FILESDIR}"/${PN}-4.9.2-no-implicit-march-flags.patch
+	"${FILESDIR}"/${PN}-4.9.2-odr.patch
+)
+
+src_configure() {
+	# need to enable LFS explicitly for 64-bit offsets on 32-bit hosts (#761100)
+	append-lfs-flags
+}
+
+src_compile() {
+	cd engine || die
+	${CONFIG_SHELL:-${BASH}} ./build.sh cxx --cxx="$(tc-getCXX)" --cxxflags="${CXXFLAGS}" -d+2 --without-python || die "building b2 failed"
+}
+
+src_test() {
+	# Forget tests, b2 is a lost cause
+	:
+}
+
+src_install() {
+	dobin engine/b2
+
+	insinto /usr/share/b2/src
+	doins -r "${FILESDIR}/site-config.jam" \
+		bootstrap.jam build-system.jam ../example/user-config.jam \
+		build kernel options tools util
+
+	find "${ED}"/usr/share/b2/src -iname '*.py' -delete || die
+
+	dodoc ../notes/{changes,release_procedure,build_dir_option,relative_source_paths}.txt
+
+	if use examples; then
+		docinto examples
+		dodoc -r ../example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3