From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-tex/pythontex/Manifest              |  3 ++
 dev-tex/pythontex/metadata.xml          | 14 +++++++++
 dev-tex/pythontex/pythontex-0.16.ebuild | 55 +++++++++++++++++++++++++++++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-tex/pythontex/Manifest
 create mode 100644 dev-tex/pythontex/metadata.xml
 create mode 100644 dev-tex/pythontex/pythontex-0.16.ebuild

(limited to 'dev-tex/pythontex')

diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
new file mode 100644
index 000000000000..1ff3efe15c15
--- /dev/null
+++ b/dev-tex/pythontex/Manifest
@@ -0,0 +1,3 @@
+DIST pythontex-0.16.tar.gz 1787147 BLAKE2B b7b765fdf681f6a757d5dc14437ae433f8310d18ad9e2efe95a8853eaf9f53e2925d7f9e45e0393eb2720019270187fb400e7a6754f18015c4ce5db8a9280729 SHA512 9a84fd7b7f568308addf9ba01c46fadfaface54b9d484c766831f1048064288fd1ecb5c56774bb0041d8f5705f8d5f8a9cd7258dc33157467eca7b3c70259183
+EBUILD pythontex-0.16.ebuild 1219 BLAKE2B 587e193da3c093ed00ede5f6d793eed9a57f0b77ab9b02f68ec4f0709a087c9f28e8b251c53249f3482e022fe10e3e4ce0268dd38d59e057320ac6ba7eb9c6a1 SHA512 f9cbb14e00b00e5357fbda39b5bac1b4a5438708059390601e57601d3fe8f5398bf9f396c829693ff0584bba6eee6577daa3df70fcd2147fbbafc9f7770aa27f
+MISC metadata.xml 455 BLAKE2B 29194bce5b2d503fcc93f46304a0473988315bda823c61ca1d63b2e0f41d4266d2197affe33bbcd46a889f5602952765a89b3236cf2cde6f0687519112b11e6c SHA512 8f87ee6e99c9cd263e6e6ec6241a463b2c3c7496a03314998015840a332fcfb3a9ebd7ac2970faa7afabde5ced10d1bdf5c553d2ae91c20bc97a0295c9250a3d
diff --git a/dev-tex/pythontex/metadata.xml b/dev-tex/pythontex/metadata.xml
new file mode 100644
index 000000000000..9586dee6f5e6
--- /dev/null
+++ b/dev-tex/pythontex/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <use>
+    <flag name="highlighting">Syntax highlighting using <pkg>dev-python/pygments</pkg></flag>
+  </use>
+  <upstream>
+    <remote-id type="github">gpoore/pythontex</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-tex/pythontex/pythontex-0.16.ebuild b/dev-tex/pythontex/pythontex-0.16.ebuild
new file mode 100644
index 000000000000..7e0fa1b75525
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.16.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latexextra-2016
+	dev-tex/pgf"
+RDEPEND="${DEPEND}
+	highlighting? ( dev-python/pygments[${PYTHON_USEDEP}] )"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	ebegin "Compiling ${PN}"
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+	eend
+}
+
+src_install() {
+	dodoc ${PN}/README "${S}"/*rst ${PN}_quickstart/*
+
+	cd ${PN} || die
+
+	installation() {
+		if python_is_python3; then
+			python_domodule {de,}${PN}3.py
+		else
+			python_domodule {de,}${PN}2.py
+		fi
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall dtx ins sty
+}
-- 
cgit v1.2.3