From 7bc9c63c9da678a7e6fceb095d56c634afd22c56 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 15 Dec 2019 18:09:03 +0000
Subject: gentoo resync : 15.12.2019

---
 dev-tcltk/tkimg/tkimg-1.4.9.ebuild | 102 +++++++++++++++++++++++++++++++++++++
 1 file changed, 102 insertions(+)
 create mode 100644 dev-tcltk/tkimg/tkimg-1.4.9.ebuild

(limited to 'dev-tcltk/tkimg/tkimg-1.4.9.ebuild')

diff --git a/dev-tcltk/tkimg/tkimg-1.4.9.ebuild b/dev-tcltk/tkimg/tkimg-1.4.9.ebuild
new file mode 100644
index 000000000000..2746c0ba15ec
--- /dev/null
+++ b/dev-tcltk/tkimg/tkimg-1.4.9.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils multilib prefix toolchain-funcs virtualx
+
+MYP=Img-${PV}-Source
+
+DESCRIPTION="Adds a lot of image formats to Tcl/Tk"
+HOMEPAGE="http://tkimg.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/1.4/${PN}%20${PV}/${MYP}.tar.gz
+	https://dev.gentoo.org/~tupone/distfiles/${PN}-1.4.7-patchset-1.tar.xz"
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test static-libs"
+
+RDEPEND="
+	dev-lang/tk:=
+	>=dev-tcltk/tcllib-1.11
+	media-libs/tiff:0=
+	>=media-libs/libpng-1.6:0=
+	>=sys-libs/zlib-1.2.7:=
+	x11-libs/libX11
+	virtual/jpeg:="
+DEPEND="${RDEPEND}
+	test? (
+		x11-apps/xhost
+		media-fonts/font-misc-misc
+		media-fonts/font-cursor-misc )"
+
+# Fails tests
+RESTRICT="test"
+
+S="${WORKDIR}/Img-${PV}"
+
+PATCHES=(
+	"${WORKDIR}"/${PN}-1.4.7-tclconfig.patch
+	"${WORKDIR}"/${PN}-1.4.7-jpeg.patch
+	"${WORKDIR}"/${PN}-1.4.7-zlib.patch
+	"${WORKDIR}"/${PN}-1.4.7-png.patch
+	"${WORKDIR}"/${PN}-1.4.7-tiff.patch
+	"${FILESDIR}"/${PN}-1.4-jpeg-9.patch
+)
+
+src_prepare() {
+	edos2unix \
+		libjpeg/jpegtclDecls.h \
+		libjpeg/Makefile.in \
+		zlib/Makefile.in \
+		zlib/zlibtcl.decls \
+		zlib/zlibtclDecls.h \
+		libpng/Makefile.in \
+		libpng/pngtclDecls.h \
+		libtiff/Makefile.in \
+		libtiff/tifftclDecls.h \
+		libtiff/tifftclStubInit.c \
+		tiff/tiff.c \
+		jpeg/jpeg.c
+	default
+	find . -name configure -delete
+
+	find compat/{libjpeg,libpng,zlib,libtiff} -delete
+
+	eautoreconf
+	for dir in zlib libpng libtiff libjpeg base bmp gif ico jpeg pcx pixmap png\
+		ppm ps sgi sun tga tiff window xbm xpm dted raw flir ; do
+		(cd $dir; eautoreconf)
+	done
+
+	eprefixify */*.h
+	tc-export AR
+}
+
+src_install() {
+	local l bl
+
+	emake \
+		DESTDIR="${D}" \
+		INSTALL_ROOT="${D}" \
+		install
+
+	if ! use static-libs; then
+		find "${ED}"/usr/$(get_libdir)/ -type f -name "*\.a" -delete || die
+	fi
+
+	# Make library links
+	for l in "${ED}"/usr/lib*/Img*/*tcl*.so; do
+		bl=$(basename $l)
+		dosym Img1.4/${bl} /usr/$(get_libdir)/${bl}
+	done
+
+	dodoc ChangeLog README Reorganization.Notes.txt changes ANNOUNCE
+
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins demo.tcl
+		insinto /usr/share/doc/${PF}/html
+		doins -r doc/*
+	fi
+}
-- 
cgit v1.2.3