From abaa75b10f899ada8dd05b23cc03205064394bc6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 22 Jan 2021 20:28:19 +0000
Subject: gentoo resync : 22.01.2021

---
 dev-tcltk/tkimg/tkimg-1.4.13.ebuild | 90 +++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 dev-tcltk/tkimg/tkimg-1.4.13.ebuild

(limited to 'dev-tcltk/tkimg/tkimg-1.4.13.ebuild')

diff --git a/dev-tcltk/tkimg/tkimg-1.4.13.ebuild b/dev-tcltk/tkimg/tkimg-1.4.13.ebuild
new file mode 100644
index 000000000000..bf3fb5a99dfd
--- /dev/null
+++ b/dev-tcltk/tkimg/tkimg-1.4.13.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools eutils multilib prefix toolchain-funcs virtualx
+
+MYP=Img-${PV}-Source
+
+DESCRIPTION="Adds a lot of image formats to Tcl/Tk"
+HOMEPAGE="http://tkimg.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/1.4/${PN}%20${PV}/${MYP}.tar.gz
+	https://dev.gentoo.org/~tupone/distfiles/${PN}-1.4.12-patchset-1.tar.gz"
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test static-libs"
+
+RDEPEND="
+	dev-lang/tk:=
+	dev-tcltk/tcllib
+	media-libs/tiff:0=
+	media-libs/libpng:0=
+	sys-libs/zlib:=
+	x11-libs/libX11
+	virtual/jpeg:="
+DEPEND="${RDEPEND}
+	test? (
+		x11-apps/xhost
+		media-fonts/font-misc-misc
+		media-fonts/font-cursor-misc )"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/Img-${PV}"
+
+PATCHES=(
+	"${WORKDIR}"/patchset-1
+)
+
+src_prepare() {
+	edos2unix \
+		libjpeg/jpegtclDecls.h \
+		zlib/zlibtclDecls.h \
+		libpng/pngtclDecls.h \
+		libtiff/tifftclDecls.h
+	default
+	find compat/libtiff/config -name ltmain.sh -delete
+
+	eautoreconf
+	for dir in zlib libpng libtiff libjpeg base bmp gif ico jpeg pcx pixmap png\
+		ppm ps sgi sun tga tiff window xbm xpm dted raw flir ; do
+		(cd $dir; AT_NOELIBTOOLIZE=yes eautoreconf)
+	done
+
+	eprefixify */*.h
+	tc-export AR
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	local l bl
+
+	emake \
+		DESTDIR="${D}" \
+		INSTALL_ROOT="${D}" \
+		install
+
+	if ! use static-libs; then
+		find "${ED}"/usr/$(get_libdir)/ -type f -name "*\.a" -delete || die
+	fi
+
+	# Make library links
+	for l in "${ED}"/usr/lib*/Img*/*tcl*.so; do
+		bl=$(basename $l)
+		dosym Img${PV}/${bl} /usr/$(get_libdir)/${bl}
+	done
+
+	dodoc ChangeLog README Reorganization.Notes.txt changes ANNOUNCE
+
+	if use doc; then
+		docompress -x usr/share/doc/${PF}/demo.tcl
+		dodoc demo.tcl
+		docinto html
+		dodoc -r doc/*
+	fi
+}
-- 
cgit v1.2.3