From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild | 50 +++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild

(limited to 'dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild')

diff --git a/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild b/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild
new file mode 100644
index 000000000000..2d202116658b
--- /dev/null
+++ b/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs
+
+MY_P="${P/_p/.update}"
+DESCRIPTION="R6RS-compliant Scheme implementation for real-time applications"
+HOMEPAGE="https://code.google.com/p/ypsilon/"
+SRC_URI="https://ypsilon.googlecode.com/files/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples threads"
+
+DEPEND="app-arch/cpio"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-asneeded.patch
+	"${FILESDIR}"/${P}-clang-cflags.patch
+)
+
+src_compile() {
+	use threads && append-flags "-pthread"
+
+	# Fix build failure with GCC 11
+	# bug #787866
+	append-cppflags -DNO_TLS
+
+	emake \
+		PREFIX="${EPREFIX}/usr" \
+		AS="$(tc-getAS)" \
+		CXX="$(tc-getCXX)" \
+		CPPFLAGS="${CPPFLAGS}" \
+		CXXFLAGS="${CXXFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	emake PREFIX="${EPREFIX}/usr" DESTDIR="${D}" install
+
+	if use examples; then
+		docinto examples
+		dodoc example/*
+	fi
+}
-- 
cgit v1.2.3