From 403387a1bc2a2d98e75bf1474b21ae379b88aab2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 17 Oct 2022 07:54:11 +0100
Subject: gentoo auto-resync : 17:10:2022 - 07:54:11

---
 dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild | 43 +++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild

(limited to 'dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild')

diff --git a/dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild b/dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild
new file mode 100644
index 000000000000..fb293dfdba44
--- /dev/null
+++ b/dev-scheme/guile-zlib/guile-zlib-0.1.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU Guile library providing bindings to zlib"
+HOMEPAGE="https://notabug.org/guile-zlib/guile-zlib/"
+SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-scheme/guile-2.0.0:=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README.org )
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# Gentoo installs zlib to /${libdir} and to /usr/${libdir}.
+	# We need /${libdir} with shared library here.
+	econf LIBZ_LIBDIR="${EPREFIX}/$(get_libdir)"
+}
-- 
cgit v1.2.3